Changing the first row of a matrix; subsequent rows depend on the first row

Question

I have generated a matrix of zeros.

tab=Table[0,{i,10},{j,10}]

tab is defined such that given tab[[1]] (the first row of tab), I am doing For[i=2,i<=10,i++,tab=ReplacePart[tab,i->2*tab[[i-1]]]] so that given the first row, all the other rows follow.

Now I have generated another table, tab1 which is a 3x10 matrix of

{{1, 1, 1, 1, 1, 1, 1, 1, 1, 1}, {2, 2, 2, 2, 2, 2, 2, 2, 2, 2}, 
 {3, 3, 3, 3, 3, 3, 3, 3, 3, 3}}

The problem is to replace the first row of tab with the first row of tab1 {1,....,1} and to calculate tab. Then doing the same with replacing the first row of tab with the second row of tab1 and then the third row of tab1. In each realization of the matrix of tab, I want to calculate the sum of each column and store the result. So in the end, I will have a 3x10 matrix of the sums of columns from each realization. [I am presenting this as a relatively simple problem as in the real problem I am trying to solve, there are about 50000 realizations of the first row of the matrix of dimensions 50x100].

I have tried

For[j = 1, j <= 3, j++, ps[j] = tab1[[j]]];
For[tab[[1]] = ps[j]; i = 2, i <= 10, i++, 
 tab = ReplacePart[tab, i -> 2*tab[[i - 1]]]]; 

but its not working. I would appreciate any help. Thank you.

Answer 1

As I understand your question, the computation can be done for one column and then rows of length 10 can be generated from that column. If that is correct, then this may be what you looking for.

Module[{t = {1, 2, 3}, sums},
  sums = Table[Total @ Thread[Times[t[[i]], {1, 2, 4}]], {i, Length @ t}];
  ConstantArray[#, 10]& /@ sums]

{{7, 7, 7, 7, 7, 7, 7, 7, 7, 7}, 
 {14, 14, 14, 14, 14, 14, 14, 14, 14, 14}, 
 {21, 21, 21, 21, 21, 21, 21, 21, 21, 21}}

Answer 2

The final result can be obtained with

Total /@ (NestList[2 # &, #, 9] & /@ tab1)

or

Plus @@@ (NestList[2 # &, #, 9] & /@ tab1)

or

Plus @@ NestList[2 # &, tab1, 9]

where 9 is the number of rows of tab minus 1. With the given value for tab1, one gets

(* {{1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023}, 
    {2046, 2046, 2046, 2046, 2046, 2046, 2046, 2046, 2046, 2046}, 
    {3069, 3069, 3069, 3069, 3069, 3069, 3069, 3069, 3069, 3069}} *)

Update

Per OP's comment

the real problem that I am trying to solve [...] is (tab, i -> 2*tab[[i - 1]]] + 4 * rnorm[[i]]) where rnorm is a matrix of random normal variables

This can be achieved for instance with

First@*Total /@ (NestList[{2 #[[1]] + 4 rnorm[[#[[2]]]], #[[2]] + 1} &, 
          {#, 2}, 9] & /@ tab1)

or

First@*Plus @@@ (NestList[{2 #[[1]] + 4 rnorm[[#[[2]]]], #[[2]] + 1} &, 
          {#, 2}, 9] & /@ tab1)

or

rnorm2 = ConstantArray[#, 3] & /@ rnorm;
First@*Plus @@ NestList[{2 #[[1]] + 4 rnorm2[[#[[2]]]], #[[2]] + 1} &, 
          {tab1, 2}, 9]

where the parameter 3 used for rnorm2 is the number of rows of tab1.

Answer 3

Whenever a computation depends upon a previous computation it is a good idea to think Fold or FoldList.

For the simple case of multiplying the previous row by two NestList works fine (and Goldberg's approach is even better) but for more complicated functions I think there is a benefit to considering FoldList.

tab1 = {{1, 1, 1, 1, 1, 1, 1, 1, 1, 1},
        {2, 2, 2, 2, 2, 2, 2, 2, 2, 2},
        {3, 3, 3, 3, 3, 3, 3, 3, 3, 3}};

The matrix generated by using tab1[[1]] as the input is

FoldList[2*#1 &, tab1[[1]], Range[9]]

which produces

and then one computes the total

Total@FoldList[2*#1 &, tab1[[1]], Range[9]]
(* {1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023} *)

To apply this to all of the rows in tab1 wrap the above step in Map using a Function to define the index into tab1.

Map[
 Function[tab1Index,
  Total@FoldList[2*#1 &, tab1[[tab1Index]], 
    Range[Length[tab1[[1]]] - 1]]
  ], Range[Length[tab1]]
 ]

resulting in

{{1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023, 1023},
 {2046, 2046, 2046, 2046, 2046, 2046, 2046, 2046, 2046, 2046},
 {3069, 3069, 3069, 3069, 3069, 3069, 3069, 3069, 3069, 3069}}

This should be fast for 50000 realizations on a 50x100 matrix.