# Expression containing $\tt{I}$ is real — how can I show this is so in my notebook?

When I solve this equation (for ϕ):

-16 y - (1 + 2 ϕ)^2 (-1 + 6 ϕ) == 0


Two solutions have imaginary parts in the symbolic expressions. However, these two can be real numbers (i.e., with a zero imaginary part), for some values of y. In particular, the second solution (using solve)

-(5/18) +
(2 (1 + I Sqrt[3])) /
(9 (-8 + 243 y + 9 Sqrt[3] Sqrt[-16 y + 243 y^2])^(1/3)) +
1/18 (1 - I Sqrt[3]) (-8 + 243 y + 9 Sqrt[3] Sqrt[-16 y + 243 y^2])^(1/3)


is real and positive (what I'm interested in) for 0 < y < 1/16. How can I make sense of it without saying "Mathematica says so" in my paper.

• FWIW, you should read about casus irreducibilis, where real quantities necessarily have complex components appearing in them, at least if you insist on a particular representation. – J. M. will be back soon Dec 14 '15 at 5:01
• en.m.wikipedia.org/wiki/Casus_irreducibilis – Sjoerd C. de Vries Dec 14 '15 at 6:38
• This is very interesting. The Casus Irreducibilis seems to be the issue. Thanks a lot! – user2757580 Dec 16 '15 at 16:50

When an expression appears to be complex but is actually real, the imaginary parts just cancel out. When a precision less than infinite is used the cancellations may not be exact and an artifact can appear showing a small imaginary component. Chop can be used to remove these artifacts.

For real positive solutions

soln = Solve[{-16 y - (1 + 2 ϕ)^2 (-1 + 6 ϕ) == 0, ϕ >
0}, ϕ, Reals]


Plot[Evaluate[Tooltip[ϕ /. soln]], {y, -1/8, 1/8},
PlotLegends -> {"y < 0", "0 < y < 1/16"}]


One can look at it from the following angle. Let us draw y=y(fi):

    Clear[z];
Manipulate[
Show[{
Plot[-(1 + 2 ϕ)^2 (-1 + 6 ϕ)/16, {ϕ, -1, 1},
PlotRange -> {-0.5, 0.5}, AxesLabel -> {"ϕ", "y"}],
Graphics[{Red, Thick, Line[{{-1, z}, {1, z}}]}]
}], {z, -0.3, 0.5}
]


yielding this:

The red line here shows the value of y. One can see that as soon as it is between two extremums, there are three solutions, all of them real, otherwise two are complex and only one real. Now this is the condition of the extremum:

 eq = D[-(1 + 2 ϕ)^2 (-1 + 6 ϕ)/16, ϕ] == 0

(* -(3/8) (1 + 2 ϕ)^2 - 1/4 (1 + 2 ϕ) (-1 + 6 ϕ) == 0  *)


This is the solution:

sl = Solve[eq, ϕ]

(*  {{ϕ -> -(1/2)}, {ϕ -> -(1/18)}}  *)


and here we get the y value corresponding to the extremums:

-(1 + 2 ϕ)^2 (-1 + 6 ϕ)/16 /. sl[[1]]
-(1 + 2 ϕ)^2 (-1 + 6 ϕ)/16 /. sl[[2]]

(*  0

16/243   *)


One concludes that three solutions take place, if 0<=y<=16/243.

Have fun!

• Oh it is fun! So you mean 3 real solutions? That seems to be "problem". Thanks. – user2757580 Dec 16 '15 at 16:48