Nested function with an increasing argument

Question

If, for example, I have a nesting function like

Nest[1 + x^n (#) &, 1, 3]

it gives the result

1 + x^n (1 + x^n (1 + x^n))

I would need the n to increase by one with every step, just like in a sum or product function, so that the result would be

1 + x^1 (1 + x^2 (1 + x^3))

Is there a way to do this in Mathematica? If so, how?

Answer 1

Module[{i = 1}, Nest[1 + x^n (#) &, 1, 3] /. n :> i++]

Or (same result)

Fold[1 + x^#2 #1 &, 1, {3, 2, 1}]

Answer 2

Taking a different approach it appears that you are seeking to apply Horner's Method to the polynomial

$$\underset{i=0}{\overset{n}{\sum }}x^{\underset{j=0}{\overset{i}{\sum }}j}$$

Taking $\underset{j=0}{\overset{i}{\sum }}j = \frac{1}{2}i(1+i)$ and making use of HornerForm a function can be created to construct the factored polynomial.

f[n_Integer?Positive] := HornerForm@Sum[x^(i (1 + i)/2), {i, 0, n}]

You are seeking f[3]

f[3]
(* 1 + x (1 + x^2 (1 + x^3)) *)

Hope this helps.

Answer 3

In case the intermediate result 1 + x^n (1 + x^n (...)) is not required,

n = 3;
First@Nest[{1 + x^#[[2]] #[[1]], #[[2]] - 1} &, {1, n}, n]

Alternative

A simpler formulation under the same assumption as above

n = 3;
Nest[1 + x^(n--) # &, 1, n]

Answer 4

I would use Fold.

Fold[1 + x^#2 (#1) &, 1, Range[3, 1, -1]]
(*  1 + x (1 + x^2 (1 + x^3))  *)

Answer 5

Two approaches with Replacement.

---

z = Nest[1 + x^n (#) &, 1, 3]
ReplacePart[z, Position[z, n][[#]] -> Defer@# & /@ Range[3]]

---

Also inspired by the @Karsten7's answer and @Eldo's Module version:

Module[{r = 3, i = 1}, 
Quiet@ReplaceRepeated[(1 + x^n), (1 + x^n) -> 1 + x^n (1 + x^n), 
MaxIterations -> r - 1] /. n :> i++]

1 + x (1 + x^2 (1 + x^3))