2
$\begingroup$

How do I draw with Mathematica a function like this?enter image description here

I would use a series of circles and find the surface.

Thanks!

$\endgroup$
2
$\begingroup$
ParametricPlot3D[{r Cos[θ], r Sin[θ], .2 RandomReal[]}, {r, 1, 2}, {θ, 0, 2 π},
  ColorFunction -> Function[y, Blend[{Red, Blue}, y]]]
$\endgroup$
3
$\begingroup$
ParametricPlot3D[{r Cos[θ], r Sin[θ], Sin[20 θ]/15}, 
 {r, 1, 2}, {θ, 0, 2 π}, 
 ColorFunction -> Function[{x, y, z, u}, Blend[{Red, Pink, LightBlue, Blue}, y]], 
 Mesh -> None, Boxed -> False, Axes -> False, PlotPoints -> 30,
 Background -> Black]

enter image description here

$\endgroup$
  • $\begingroup$ Very nice, +1, but I think there should be a certain amount of randomness somewhere $\endgroup$ – eldo Dec 1 '15 at 22:57
2
$\begingroup$

Just play with it, using functions with periods that divide 2 Pi:

ParametricPlot3D[{r Cos[θ], r Sin[θ], 
  0.015 (Sin[7 θ + 10 r Cos[2 θ]] + Sin[5 θ + 10 r Sin[2 θ]]) + 
   0.025 Sin[30 θ + Sin[θ]] + (r - 2)^2 Cos[3 θ + 0.73] - 0.15 r},
 {r, 2, 3}, {θ, 0, 2 π},
 Mesh -> None, 
 ColorFunction -> Function[{x, y, z, r, θ}, 
   ColorData["ThermometerColors"][y]],
 PlotPoints -> {15, 60}, PlotRangePadding -> {0, 0, 0.5}, 
 Background -> Black, Boxed -> False, Axes -> False]

Mathematica graphics

(I mean, it's not like an anatomy lesson.)

$\endgroup$
  • $\begingroup$ Nicely done. (+1) $\endgroup$ – Edmund Dec 2 '15 at 0:28

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.