Series expansion with irrational power

Question

I need the series expansion of a fairly nasty function and its derivative:

f = (x - a) (1 + b (1/(x - a))^((5 + Sqrt[73])/12) *
   Hypergeometric2F1[(-7 + Sqrt[73])/12, (1 + Sqrt[73])/12, (
   6 + Sqrt[73])/6, -(a/4)/(x - a)]) + a/2

$f\left(x\right) = (x-a) \left(1+b \left(\frac{1}{x-a}\right)^{\frac{1}{12} \left(5+\sqrt{73}\right)} \, _2F_1\left(\frac{-7+\sqrt{73}}{12} ,\frac{1+\sqrt{73}}{12} ;\frac{6+\sqrt{73}}{6} ;-\frac{a}{4 (x-a)}\right)\right)+\frac{a}{2}$

where $x$, $a$ and $b$ are positive real numbers and I know $x \gg a$. I'm interested in the series expansion of $f$ and $f'$ in inverse powers of $x$:

Series[f, {x, \[Infinity], 1}] // Normal

$\dfrac{b \left(\dfrac{1}{x-a}\right)^{\dfrac{\sqrt{73}}{12}}}{\left(\dfrac{1}{x}\right)^{7/12}}-\dfrac{a}{2}+x$

Series[D[f, x], {x, \[Infinity], 1}] // Normal

$b \left(\dfrac{1}{x}\right)^{5/12} \left(\dfrac{1}{x-a}\right)^{\dfrac{\sqrt{73}}{12}}+1$

The problem is I can't figure out how to get this to simplify any further. I need to get these in the form

$ c_1 x + c_0 + \dfrac{c_{-1}}{x^{p}} $

for some constants $c_i$ and $p$, but Series doesn't expand the term with $x-a$ in the denominator. I guess because the power is irrational? How can I get the answer in the desired form? I could do it by pen and paper of course, but I would love to have it in code. Using Assumptions -> {x > a > 0, b > 0} doesn't seem to make any difference.

Any help is appreciated.

Answer 1

After you define your function execute this line:

Series[f, {x, \[Infinity], 1}] // Normal // PowerExpand

Following your $x \gg a$ we can rewrite it as

% /. (-a + x) -> x // FullSimplify

which gives:

Now you have to be very careful dealing with derivative. It is not enough to keep 0th and 1st terms (as you did) - you will loose information. It is very interesting that to get correct result you need to keep as much as 4 terms:

Series[D[f, x], {x, \[Infinity], 3}] // Normal // PowerExpand // FullSimplify

Carefully examining the above expression with respect to $x \gg a$ we rewrite it as

% /. a -> 0 // FullSimplify

which gives:

And now it is correct because derivative of the function series is equal to the series of the derivative:

Answer 2

You can do a series expansion about $a=0$.

Series[f, {a, 0, 1}] // Normal // PowerExpand // Collect[#, x, Simplify] &

$$ -\frac{a}{2}+x+b x^{\frac{1}{12} \left(7-\sqrt{73}\right)}-\frac{\left(-91+\sqrt{73}\right) a b x^{-1+\frac{1}{12} \left(7-\sqrt{73}\right)}}{48 \left(6+\sqrt{73}\right)} $$

Series[D[f, x], {a, 0, 1}] // Normal // PowerExpand // Collect[#, x, Simplify] &

$$ 1-\frac{\left(191+43 \sqrt{73}\right) a b x^{-2+\frac{1}{12} \left(7-\sqrt{73}\right)}}{288 \left(6+\sqrt{73}\right)}-\frac{1}{12} \left(-7+\sqrt{73}\right) b x^{-1+\frac{1}{12} \left(7-\sqrt{73}\right)} $$

Then you can manually discard the $O(\frac{a}{x})$ correction to the $x^{-p}$ term.

I did a little bit more exploration, and found that if you series expand to higher order in $a$ then the extra terms are all $O((\frac{a}{x})^n)$ corrections to the $x^{-p}$ term.