Show Factorial instead of Gamma in the result of RSolve

Question

Now I wanted to solve for a recurring function with RSolve. Here's how I tried:

RSolveValue[{a[n] == n*a[n - 1] - n!, a[0] == 2}, a[n], n]
(*2 Pochhammer[1, n] - n Pochhammer[1, n]*)
Simplify[%, Element[n, Integers]]
(* -(-2 + n) Pochhammer[1, n] *)
FunctionExpand[%]
(* -(-2 + n) n Gamma[n] *)

Actually the result should be $(2-n)n!$, but how can I simplify the result by assuming n be positive, so the result could look nicer.

Answer 1

You can increase penalty for Gamma and Pochhammer headers:

simplify[expr_, n_] := 
  FullSimplify[expr, n ∈ Integers && n > 0, 
   ComplexityFunction -> ((LeafCount@# + 
        10 Count[#, _Gamma | _Pochhammer, {0, ∞}]) &)];

simplify[RSolveValue[{a[n] == n*a[n - 1] - n!, a[0] == 2}, a[n], n], n]
(* -(-2 + n) n (-1 + n)! *)

Answer 2

Don't know if this suits your needs or not, but if you are certain that the argument to Gamma is a non-negative integer, then just make the replacement manually

RSolveValue[{a[n] == n*a[n - 1] - n!, a[0] == 2}, a[n], n]
(* 2 Pochhammer[1, n] - n Pochhammer[1, n] *)

Simplify[%, Element[n, Integers]]
(* -(-2 + n) Pochhammer[1, n] *)

FunctionExpand[%]
(* -(-2 + n) n Gamma[n] *)

% /. n Gamma[n] -> Factorial[n]
(* -(-2 + n) n! *)

Answer 3

rsv = RSolveValue[{a[n] == n*a[n - 1] - n!, a[0] == 2}, a[n], n]

2 Pochhammer[1, n] - n Pochhammer[1, n]

Simplify`SimplifyGamma @ rsv

2 n! - n n!

Developer`GammaSimplify @ rsv

2 n! - n n!

Answer 4

Does appending

/. Gamma -> (x |-> Factorial[x - 1]) // Simplify

work?

PS You may need to do previously:

$Assumptions = {n \[Element] Integers, n > 0};