0
$\begingroup$

I tried to calculate

Integrate[(9.07 - 5.60 Cos[.87 t] - 2.71 I Sin[.87 t] + 
   2.14 Cos[1.74 t] + 2.70 I Sin[1.74 t]  )^0.5, {t, 0, T}]

but the output is the same as input! If I remove the power (.5), it works; otherwise it gives me the input! Also, when I try to expand an expression with non-integer power, the output is the same as input. For example,

Expand[(x+y)^0.2] 

yields

(x+y)^0.2,

but

Expand[(x+y)^2] 

yields

x^2+y^2+2xy.

$\endgroup$
4
  • $\begingroup$ Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! $\endgroup$
    – Michael E2
    Nov 22, 2015 at 22:03
  • 2
    $\begingroup$ (1) It might help if you used exact coefficients and powers. The power 0.5 is an approximate real number representing the exact number 1/2 to machine precision. The rules for dealing with approximate exponents are more restrictive than those for exact ones. (2) What do you expect to get from Expand[(x+y)^0.2]? A power series? $\endgroup$
    – Michael E2
    Nov 22, 2015 at 22:07
  • $\begingroup$ Not possible to integrate in term of elementary and/or elliptic functions. But NIntegrate[(9.07 - 5.60 Cos[.87 t] - 2.71 I Sin[.87 t] + 2.14 Cos[1.74 t] + 2.70 I Sin[1.74 t])^0.5, {t, 0, 2 [Pi]/0.87}] yields 21.3834 as an answer $\endgroup$
    – yarchik
    Nov 22, 2015 at 22:39
  • 3
    $\begingroup$ What do you expect (x+y)^0.2 to expand to? $\endgroup$
    – march
    Nov 22, 2015 at 22:48

2 Answers 2

2
$\begingroup$

Since the power is not an integer, for Expand[(x+y)^0.2] you can use Binomial series.

   r = Sum[Binomial[.2, k] x^k y^(.2 - k), {k, 0, Infinity}]
   (* 1. y^0.2 HypergeometricPFQ[{-0.2}, {}, -((1. x)/y)] *)

To verify

   r /. {x -> 10, y -> 99}
   (* 2.55556 *)
   (x + y)^(0.2) /. {x -> 10, y -> 99}
   (*2.55556*)

Here are few terms in the 'expansion'

  Plus @@ Table[ Binomial[.2, k] x^k y^(.2 - k), {k, 0, 10}]

Mathematica graphics

reference http://mathworld.wolfram.com/BinomialSeries.html

btw, it is better to make one post per question. the above for your second question in the same post.

$\endgroup$
1
$\begingroup$

The fact that Mma returns the input means that it is not able to fulfill the task. In other words there is no analytical expression for your integral, but you might agree to get it numerically. Try this:

    lst = Table[{T, 
   NIntegrate[(9.07 - 5.60 Cos[.87 t] - 2.71 I Sin[.87 t] + 
       2.14 Cos[1.74 t] + 2.70 I Sin[1.74 t])^0.5, {t, 0, T}]}, {T, 0,
    1, 0.05}]

(* {{0., 0.}, {0.05, 0.118419 + 0.000616924 I}, {0.1, 
  0.236793 + 0.00246022 I}, {0.15, 0.355074 + 0.00550748 I}, {0.2, 
  0.473219 + 0.00972146 I}, {0.25, 0.591183 + 0.0150502 I}, {0.3, 
  0.708926 + 0.0214273 I}, {0.35, 0.826406 + 0.0287722 I}, {0.4, 
  0.943589 + 0.0369902 I}, {0.45, 1.06044 + 0.0459733 I}, {0.5, 
  1.17693 + 0.0556005 I}, {0.55, 1.29304 + 0.0657383 I}, {0.6, 
  1.40875 + 0.0762412 I}, {0.65, 1.52406 + 0.0869532 I}, {0.7, 
  1.63896 + 0.0977077 I}, {0.75, 1.75346 + 0.108329 I}, {0.8, 
  1.86758 + 0.118636 I}, {0.85, 1.98137 + 0.128438 I}, {0.9, 
  2.09487 + 0.137543 I}, {0.95, 2.20814 + 0.145756 I}, {1., 
  2.32127 + 0.152885 I}}  *)

The result is the table with the structure {T, integral} . I did this list from 0 to 1 with respect to T, since you did not give numbers of interest, but you can choose any boundaries. Now one can plot it:

    Row[{ListPlot[lst /. {x_, y_} -> {x, Re[y]}, 
   AxesLabel -> {Style["T", 16, Italic], 
     Style["Re[int]", 16, Italic]}, ImageSize -> 250], Spacer[20], 
  ListPlot[lst /. {x_, y_} -> {x, Im[y]}, 
   AxesLabel -> {Style["T", 16, Italic], 
     Style["Im[int]", 16, Italic]}, ImageSize -> 250]}]

yielding the following:

enter image description here

Now we see that the dependencies are rather simple and one can fit the with some reasonable analytical functions, if necessary. These functions then will serve good approximations for your integral. I do not know, if you need that though.

Have fun!

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.