Putting two functions in one manipulate plot

Question

I have a problem that is somewhat related to this https://stackoverflow.com/questions/7727668/putting-two-plots-in-a-manipulate-whilst-keeping-the-plots-visible but I would like to plot two functions in one plot.

 Clear[x, μ, ξ, β, γ, rp, sp, λCrp, λCsp , λlower];
 Clear[ c, yp, λ, α, ϵp, ηp, ep];
 rp = ϵp*λ + (1 - ηp)*(1 - λ);
 sp = ηp*(1 - λ) + (1 - ϵp)*λ;
 λCrp = (ϵp*λ)/(ϵp*λ + (1 - ηp)*(1 - λ));
 λCsp = (ηp*(1 - λ))/(ηp*(1 - λ) + (1 - ϵp)*λ);

 (* Two Functions *)
 λlower = λ /. Solve[rp*(yp - ep - c + α*λCrp) + sp*(yp - ep + α*(1 - λCsp)) == yp + α*(1 - λ), {λ}]
 λupper =λ /. Solve[rp*(yp - ep - c + α*λCrp) + sp*(yp - ep + α*(1 - λCsp)) == yp + α*(1 - λ), {λ}]

 (* Properties - Visualization of Values for λlower *)
 Manipulate[λ /. Solve[rp*(yp - ep - c + α*λCrp) + sp*(yp - ep + α*(1 - λCsp)) == yp + α*(1 - λ), {λ}], {ep, 0, α}, {c, 0, α}, {α, 0, 1}, {ϵp, 0.5, 1}, {ηp, 0.5, 1}]
 Manipulate[Plot[λ /. Solve[rp*(yp - ep - c + α*λCrp) + sp*(yp - ep + α*(1 - λCsp)) == yp + α*(1 - λ), {λ}], {λ, 0,1}], {ep, 0, α}, {c, 0, α}, {α, 0, 1}, {ϵp, 0.5, 1}, {ηp, 0.5, 1}]

 (* Properties - Visualization of Both Values in One Plot *)
 (* Not working for both - λlower, λupper *)
 Manipulate[Plot[{Evaluate[λ /. Solve[Rationalize[rp (yp - ep - c + α λCrp) + 
      sp (yp - ep + α(1 - λCsp)) ==  yp + α(1 - λ)], {λ}][[1]] /. {ϵp -> ϵpa, ηp -> ηpa}], {λ, 0, 1}},{Evaluate[λ /. Solve[Rationalize[rp (yp - ep - c + α λCrp) + 
      sp (yp - ep + α(1 - λCsp)) ==  yp + αλ - c], {λ}][[1]] /. {ϵp -> ϵpa, ηp -> ηpa}], {λ, 0, 1}}], {ep, 0, α}, {c, 0, α}, {α, 0,1}, {ϵpa, 1/2, 1}, {ηpa, 1/2, 1}]          

The code does not work and therefore I do not know if there would be different colors assigned by default. If not, can I specify the color for each function?

Thank you!

Answer 1

One thing I'd suggest is do not put Solve inside Manipulate if you don't really need to. In this case the expressions can be easily solved symbolically beforehand. Also you should specify initial values for your parameters so that you don't throw an error on first evaluation:

These now work fine.

 Clear[r1]
 r1[ep_, α_, ηp_, c_, ϵp_] = λ /. 
       First@Solve[rp*(yp - ep - c + α*λCrp) +
       sp*(yp - ep + α*(1 - λCsp)) == 
       yp + α*(1 - λ), {λ}];
 Manipulate[r1[ep, α, ηp, c, ϵp],
    {{ep, 0}, 0, α}, {{c, 0}, 0, α}, {{α, 1/2}, 0, 1}, 
    {{ϵp, .75}, 0.5, 1}, {{ηp, .5}, 0.5, 1}]
 Manipulate[
     Plot[r1[ep, α, ηp, c, ϵp], {λ, 0, 1}],
       {{ep, 0}, 0, α}, {{c, 0}, 0, α}, {{α, 1/2}, 0, 1}, 
       {{ϵp, .75}, 0.5, 1}, {{ηp, .5}, 0.5, 1}]

Note your plot is rather uninteresting since you have solved for Lambda, r1 always has a constant value..

In your last case you have additionally used incorrect syntax for plotting multiple functions. You should do

 Plot[  { f1[lambda],f2[lambda] } , {lambda,0,1 } ]

or

 Show[{ Plot[f1[lambda],{lambda,0,1 }],Plot[f2[lambda],{lambda,0,1 }]}]

not

 Plot[  { f1[lambda],{lambda,0,1 } } ,{ f2[lambda]  ,{lambda,0,1 }}  ]