Listing all usage messages from a loaded package

Question

I am writing several packages in collaboration with others. In order to help the group use my packages, I want to provide them with a simple reference of function names and usage messages. How can I best do this?

Additional information:

Although I didn't originally ask for it, I'd like to be able to do the following:

1. save the function names with their usage messages
2. into some text-based file (e.g. LaTeX, HTML, markdown, plain text)
3. that organizes the functions under section headings that specify which package they came from.

Here's what it might look like in plain text:

PackageName1

function1 :: does something
function2 :: does something else

PackageName2

function3 :: does it do something?
function4 :: does, perhaps, something

Formatted versions like LaTeX that require compiling are, perhaps, less useful to the community, but they just look so nice :)

Answer 1

A bit cleaner I believe:

Cases[
  MakeExpression @@ {Names @ "entropy`*"},
  _[s_] :> Row[{HoldForm[s], " :: ", s::usage}]
]

• If you need a String rather than a Row expression you can use ToString @ Row[ but first try it this way.

• Unlike your code this will work even if Symbols have OwnValues assignments.

Answer 2

Thanks to the comment by @Kuba, I was able to write this complex "one" line, which is what I wanted.

(#::usage) & /@ Symbol /@ Names["entropy`*"] // 
  MapThread[StringJoin, {(# <> " :: ") & /@ Names["entropy`*"], #}] &

If you have any suggestions to make the solution more elegant solution, please comment and I'll update it. In particular, my method of combining the strings feels clunky, as does calling Names[] twice.

Edit:

I agree that Mr. Wizard's answer is better. Here's how I used it to export the usage messages for a list of packages to a plain text file.

packageNameList = 
  {
    "utility",
    "greenSheet",
    "entropy"
  };
packageList =
  ( # <> "`*") & /@
    packageNameList;
doc = OpenWrite["doc.txt"];
For[i = 1, i <= Length[packageList], i++,
  Export[doc, "\n\nPackage: " <> packageNameList[[i]] <> "\n\n"];
  Cases[
    MakeExpression @@ {Names@packageList[[i]]}, _[s_] :> 
      ToString@Row[{"\n\n", HoldForm[s]," :: ", s::usage}]
  ] //
    Export[doc, #, "List"] &
]