How to specify the centre or PlotRange of a Graphics3D?

Question

When I create a Graphics3D, I often want to place an object right at the centre of the box. Initially I thought that the centre was specified by {0, 0, 0}, but I soon realised that this is actually the corner.

I've realised that I can find the centre by dividing the dimensions of the box in half. For example if

PlotRange -> {{0, 100}, {0, 100}, {0, 100}}

then if I want to put my Sphere dead centre I'll put it at:

Sphere[{100/2, 100/2, 100/2, 1]

This is all very well if I explicitly know the dimensions of the box, but if I don't know the PlotRange, how can I ensure that my object is placed right at the centre?

Is there a way to tell the size of the PlotRange if you haven't specified it explicitly?

For example, consider this function:

balls = Table[Sphere[RandomReal[{0, 100}, 3], 1], {50}]~
   Join~{Sphere[{50, 50, 50}, .05]};
Manipulate[
 Graphics3D[
  balls,
  ViewPoint -> {1.3*10^-zoom, -2.4*10^-zoom, 2*10^-zoom}, 
  SphericalRegion -> True, 
  PlotRange -> {{0, 100}, {0, 100}, {0, 100}}],
 {zoom, 0, 3}]

The slider controls the zoom, which in this function zooms in all the way until you hit a very small sphere. For this to work though, the sphere needs to be precisely at the centre of the plot. To ensure this precision, I manually entered the size of the plot (PlotRange -> {{0, 100}, {0, 100}, {0, 100}}), as well as manually control the placement of the middle sphere (Sphere[{50, 50, 50}, .05]).

Is there a way to make sure that this sphere is placed right at the very centre of the box without needing to manually specify either the dimensions of the PlotRange or the coordinates of the centre sphere?

I hope this clarifies what I'm trying to get at.

Answer 1

Like bobthechemist says you have to use ViewCenter to specify what point you want to zoom in on without specifying any absolute coordinates. For example in ViewCenter->{0.5,0.5,0.5} the 0.5 means 50 percent of the plot range in the x, y and z direction respectively.

Similarly when you position objects you have to give their position in a number of percent of the plot range. This way, again, you don't have to know what the plot range is. This is realized with Scaled, like this:

balls = Join[
   Table[Sphere[RandomReal[{0, 100}, 3], 1], {50}],
   {Green, Sphere[Scaled[{0.5, 0.5, 0.5}], .05]}
   ];
Manipulate[
 Graphics3D[balls, 
  ViewPoint -> {1.3*10^-zoom, -2.4*10^-zoom, 2*10^-zoom},
  ViewCenter -> {0.5, 0.5, 0.5},
  SphericalRegion -> True
  ], {zoom, 0, 3}
 ]