Is there a way to make the "Details" section of the Documentation expanded by default?

Question

By default, the Mathematica documentation opens with the "Details" section collapsed.

This is never what I'm looking for — in fact, I've lost count of the times I've sought help on a feature and not found it anywhere on the feature's Documentation page (at least not until I remember this shortcoming).

Is there a way to configure Mathematica so that the "Details" section of the Documentation is always expanded by default?

Answer 1

V11+ notes

Stylesheet solution does not seem to work and the section repeatedly opens and closes. I am not sure why yet.

If you are fine with details section permanently opened you can edit "Notebook" style and add:

NotebookDynamicExpression :> Refresh[
  CurrentValue[EvaluationNotebook[], {TaggingRules, "Openers", "NotesSection"}] = True
  ,
  None
]

I was expecting it to work fine but somehow the section can't be closed (is reopened).

Update 2015, stylesheet approach:

We can safely customize basic stylesheets by copying them first to $UserBaseDirectory:

styleDir = FileNameJoin[{"SystemFiles", "FrontEnd", "StyleSheets", "Wolfram"}]

If[! DirectoryQ@#, CreateDirectory@#] &@ FileNameJoin[{$UserBaseDirectory, styleDir}]


CopyFile @@ (
  FileNameJoin[{#, styleDir, "Reference.nb"}] & /@ {
   $InstallationDirectory, $UserBaseDirectory}
 )

SetOptions[NotebookOpen @ %, {Editable -> True, Saveable -> True}]

Now find "NotesSection" style definitions and add there

CellDynamicExpression :> Refresh[
  SelectionMove[EvaluationCell[], All, CellGroup];
  FrontEndExecute[ FrontEndToken[EvaluationNotebook[], "OpenCloseGroup"]]
  ,
  None
]

Save and done.

---

Old answer, programmatic approach

The idea is to capture F1 (take a look at the link at the bottom) and include a code that will expand this cell group.

I have not fully tested it (and I probably won't :P) but this works so far:

V9:

    Unprotect[Documentation`HelpLookup];
    Documentation`HelpLookup[link_String, nb_, lang_String, opts : OptionsPattern[]
     ] := Block[{$inblock = True, test},

                test = Documentation`HelpLookup[link, nb, opts];
                NotebookFind[test, "NotesSection", All, CellStyle];
                FrontEndTokenExecute[test, "OpenCloseGroup"]

               ] /; ! TrueQ[$inblock]

90% of credits goes to Simon Woods for this answer

One can put it to the init.m file so this becomes a default behaviour. I've never done this but I will try one day.

I was trying to do this via Cells[test, CellStyle->"NotesSection"] but it was terminating the session repeatedly.

This works on Win7 V9 but not on V8. Any comments appreciated.

V8:

I can't test it and it is ugly but works on V8, thanks Michael Hale for help:

Unprotect[Documentation`HelpLookup];
Documentation`HelpLookup[link_String, nb_, lang_String, opts : OptionsPattern[]
   ] := Block[{$inblock = True, test},

   Documentation`HelpLookup[link, nb, opts];
   Pause[1];
   test =
    Select[Notebooks[], (("DocumentType" /. NotebookInformation[#]) ===
          "Help") &][[1]];
   NotebookFind[test, "NotesSection", All, CellStyle];
   FrontEndTokenExecute[test, "OpenCloseGroup"]] /; ! TrueQ[$inblock]

Unfortunatelly I can't make it work without Pause since I can;t test it. If I find V8 among my friends I will try to make a proper code.

Answer 2

Based on Kuba's findings in this and this answers and also thanks to user1950580 who uncovered FrontEnd`Private`SetCurrentValue (his answer was the only place where this function was listed), here is my modification of Kuba's stylesheet approach which works well with version 11.1 and is tuned on to influence other versions installed as little as possible. In order to prevent the appearance of the dialog

in earlier versions (the above screenshot is from version 8 installed on the same machine) when opening the Documentation center (which automatically opens modified "Reference.nb" stylesheet), I Export new stylesheet as "Package".

Here is the code:

systemStyleSubDir = FileNameJoin[{"SystemFiles", "FrontEnd", "StyleSheets", "Wolfram"}];

If[! DirectoryQ@#, CreateDirectory@#] &@
  FileNameJoin[{$UserBaseDirectory, systemStyleSubDir}];

Export[FileNameJoin[{$UserBaseDirectory, systemStyleSubDir, "Reference.nb"}],
 Notebook[{
   Cell[StyleData[
     StyleDefinitions -> 
      FrontEnd`FileName[{$InstallationDirectory, "SystemFiles", "FrontEnd", "StyleSheets",
         "Wolfram", "Reference.nb"}]]],
   Cell[StyleData["NotesSection"],
    CellDynamicExpression :> FEPrivate`If[FEPrivate`Equal[FEPrivate`$VersionNumber, 11.1],
      FrontEnd`Private`SetCurrentValue[
             FrontEnd`ButtonNotebook[], {TaggingRules, "Openers", "NotesSection"}, 
       True]]]},
  StyleDefinitions -> "PrivateStylesheetFormatting.nb"], "Package"]

Note that Refresh isn't necessary here. I also use safe FrontEnd`ButtonNotebook[] instead of dangerous SelectedNotebook[] with which the above CellDynamicExpression will modify not exclusively the Documentation Notebook from where it is running, but any selected or currently evaluating Notebook if a Cell with the modified "NotesSection" style is currently displayed on the screen...