Solving system of two equations

Question

For $\mu \in (-\infty,-\frac{\pi^{2}}{6})$, I need to solve for $T$ and $\mu$ the system

$$ \frac{1}{2}A =\frac{2T}{\sqrt{-(\frac{\pi^{2}}{3} + 2\mu)}}\arctan{\frac{\pi}{\sqrt{-(\frac{\pi^{2}}{3} + 2\mu)}}}$$ and

$$ \frac{1}{2}E =\pi T + \frac{\mu}{2}A $$

Naively asking Solve to do this does not yield a result. I then considered restricting the domain $\mu \in [-\pi^2,-\pi^2 +\epsilon], \epsilon << 1$ and taking the linear series approximation at $\mu=-\pi^2$ to get $\tan ^{-1}\left(\sqrt{\frac{2}{3}}\right)+\frac{2 \sqrt{\frac{2}{3}} \left(\mu +\pi ^2\right)}{5 \pi ^2}+O\left(\left(\mu +\pi ^2\right)^2\right)$ and then asking Solve again to do this, but this yielded a very long result that I do not understand.

Simplify[
 Solve[energy/2 == \[Pi]  T + \[Mu]/2 waveaction && 
   waveaction/
    2 == (2  T)/
     Sqrt[-(\[Pi]^2/3 + 2 \[Mu])] (ArcTan[Sqrt[2/3]] + (
       2 Sqrt[2/3] (\[Mu] + \[Pi]^2))/(
       5 \[Pi]^2)), {T, \[Mu]}]]

Any ideas on how to do this?

Answer 1

I think there is no simple closed formula for this problem, you should be satisfied with numeric solution. So I will just outline how NSolve can be used.

eq=(A/2==(2 T ArcTan[\[Pi]/Sqrt[-(\[Pi]^2/3)-2 \[Mu]]])/Sqrt[-(\[Pi]^2/3)-2 \[Mu]]&&e/2==\[Pi] T+(A \[Mu])/2)

Unknown variables are $T$ and 𝜇, whereas $A$ and $e$ are given parameters.

First eliminate $T$:

mueq = Eliminate[eq, T]

This is a complicated transcendental equation for 𝜇, there is no hope of obtaining analytic formula. But if you give numerical values to the parameters $A$ and $e$, MMA can numerically find 𝜇. For example,

cond = {A -> 0.2, e -> -10};
musols = NSolve[(mueq /. cond) && \[Mu] < -Pi^2/6, \[Mu], Reals]

(* {{\[Mu] -> -25.0418}} *)

Flatten[Table[Join[musol,#]&/@Solve[eq[[2]] /.cond /.musol, T], {musol,musols}], 1]

(* {{\[Mu] -> -25.0418, T -> -0.794446}} *)

Depending on parameters $A$ and $e$, the number of solutions to mueq may change. For example, there is no solution for cond = {A -> 1, e -> 20}.