How do I use Mathematica as a vector drawing program?

Question

Recently I changed my furniture in my room and I am trying to find the best position of each part. I am sure that Mathematica could help! I read the LocatorPane, selecting multiple Locators for selecting multiple locators.

Then I made some shapes like a triangle (3 Locators), a table (4 Locators) etc. and tried to move them(each shape as a whole) in some direction.

My questions are:

• How can one group/ungroup some of the shapes (for examples table + chairs)

• Rotate a shape to a particular angle

• Ensure that two sides of the same or different shapes are in parallel,vertical or tangent?

Answer 1

I think it is fun and maybe even useful for domestic purposes so this is my approach.

The following code allows you to easily manage rotation of objects. So it is reffering to your second question. I have not put this in neat DynamicModule because it is not finished, I consider it a sample piece of code :)

x = {0, 0}; y = {1, 1}; (*starting positions*)
Do[rot@i = 0, {i, 2}]; (*starting rotations*)
acc = 1;
ob[o_, id_] :=  EventHandler[Rotate[#, rot[id]] &@
                              Style[o, If[acc == id, Red, Blue]], 
                             {"MouseDown" :> (acc = id)}, 
                             PassEventsDown -> True, PassEventsUp -> True]
(*ob is wrapper for your chairs etc.*)

Grid[{
      {LocatorPane[Dynamic@{x, y},
                   Graphics[{
                             Dynamic@ob[Rectangle[x - 1, x + 1], 1],
                             Dynamic@ob[Rectangle[y - 1, y + 1], 2]
                            }, PlotRange -> 10, ImageSize -> 500, Axes -> True]
                  ]
      ,
       Column[{
               StringForm["Object ``", Dynamic@acc],
               Experimental`AngularSlider[Dynamic[rot[acc]]],
               InputField[Dynamic[rot[acc]], FieldSize -> 6]
              }, Center]
      }
     }]

• The active object is Red and you can switch it by click, no problem with adding SetterBar or whatever next to the plot.
• Active object is annouced by variable acc which enables color rot and so on.
• You can easily add other parameters which you want to be able to manage.

Experimental``AngularSlider is just for fun. It's Options do not work correctly but here it is only for it's appearance :)

Maybe it is a mess and there is not much information but I think no one is expecting that answers here will consist of complete interior design tools :)

You can use it $+$ Heike's code about multiple selection $+$ couple tiny improvements $=$ it could be something.

Answer 2

I think it's an interesting question - even if I wouldn't use Mathematica for this purpose. I'm assuming you're not interested so much in the interactive drawing tools (you can group things together, but there's no numerical interactivity like you'd find in a CAD program). Sticking with 2D to start with:

chair = {Gray, Rectangle[{0, 0}, {.5, .5}]};
table = {Gray, Rectangle[{0, 0}, {1, 1}]};
bed = {Gray, Rectangle[{0, 0}, {2, 1}]};
carpet = Inset[
   ArrayPlot[
    CellularAutomaton[{14, {2, 1}, {1, 1}}, {{{1}}, 0}, {{{30}}}], 
    ColorFunction -> "LakeColors"]];
room = {EdgeForm[Black], FaceForm[None], Rectangle[{0, 0}, {7, 5}]};
Graphics[
 {room, 
  Translate[carpet,  {0, 0}],
  Translate[Rotate[chair, Pi],  {6.25, 4}], 
  Translate[Rotate[table, Pi/2], {6, 2.5}],
  Translate[bed, {0.1, 3.9}]
  },
 Frame -> True]

If you feel the urge to re-arrange things manually from here, then use the commands on the Graphics menu.

It's possible to add Locators and Sliders to enable some interactivity:

Manipulate[
 Graphics[
  {room, 
   Translate[carpet, {0, 0}],
   Translate[Rotate[chair, rot1], loc1], 
   Translate[Rotate[table, rot2], loc2],
   Translate[bed, {0.1, 3.9}]
   },
  Frame -> True],
 {{rot1, 0, "Orientation of chair"}, 0, 2 Pi},
 {{rot2, 0, "Orientation of table"}, 0, 2 Pi},
 {{loc1, {0, 0}}, Locator, Appearance -> None},
 {{loc2, {0, 0}}, Locator, Appearance -> None}]

you can drag the chair and table around now. It's not looking promising though.