How can I build a GraphicsGrid of arbitrary size?

Question

This is actually a very simple scenario, in order to make simpler this question Part I.

Consider the following piece of Mathematica code

data1 = {{-1, 2}, {3, 1}};
data2 = {{1, -5}, {2, -1}};
data3 = {{0, 1}, {-3, 4}};
data4 = {{-4, 9}, {8, 10}};
data5 = {{-2, 5}, {-2, -5}};
data6 = {{-5, -3}, {0, 1}};
data7 = {{-1, -2}, {-1, 1}};
data8 = {{2, 9}, {7, 1}};

L1 = ListPlot[data1];
L2 = ListPlot[data2];
L3 = ListPlot[data3];
L4 = ListPlot[data4];
L5 = ListPlot[data5];
L6 = ListPlot[data6];
L7 = ListPlot[data7];
L8 = ListPlot[data8];

P0 = GraphicsGrid[{{L1, L2, L3}, {L4, L5, L6}, {L7, L8}}, ImageSize -> 550]

The simple two elements lists could be massive external data files. So, my question is: If I don't know the exact number of data files beforehand (in my case for example, it could be anything between 0 and 8), how can I define the GraphicsGrid? If a list (file) is missing then I will get an empty slot in the grid. Is it possible to fit the empty slot with the next available item, but maintaining the grids's original structure (3 rows, the first 2 with 3 plots per row and the last one with only 2 plots)?

EDIT

I see that the use of lists is not helpful because it does not match to the actual case. So, let me explain the situation: I run a FORTRAN program which produces 8 data files. However, there are cases in which the number of produced files is smaller than 8, even zero but never larger than 8. So in order to plot these files I constructed this code. However, many complained about this and for this reason let's suppose the following:

SetDirectory[];

data1 = Import["data1.ab","Table"];
data2 = Import["data2.cd","Table"];
data3 = Import["data3.ef","Table"];
data4 = Import["data4.gh","Table"];
data5 = Import["data5.ij","Table"];
data6 = Import["data6.kl","Table"];
data7 = Import["data7.mn","Table"];
data8 = Import["data8.op","Table"];

L1 = ListPlot[data1];
L2 = ListPlot[data2];
L3 = ListPlot[data3];
L4 = ListPlot[data4];
L5 = ListPlot[data5];
L6 = ListPlot[data6];
L7 = ListPlot[data7];
L8 = ListPlot[data8];

P0 = GraphicsGrid[{{L1, L2, L3}, {L4, L5, L6}, {L7, L8}}, ImageSize -> 550]

The structure of the grid corresponds to the case where all 8 files are present. What I want is an automatic procedure reading every available data file, determine which of them are present (not empty) and then plot them in a grid.

Answer 1

not sure if this is what you wanted to or....

Manipulate[
 data = Table[ListPlot[RandomReal[{0, 1}, {20}], Joined -> True,Mesh -> True],
        {nFiles}];
 makeGrid[data],

 {{nFiles, 3, "how many files?"}, 1, 50, 1,Appearance -> "Labeled"},(*must start at 3*)
 Initialization :>
  (
   makeGrid[data_List] := Module[{d = data, nCol = 3, over},
      over = Mod[Length[d], nCol];
      If[over > 0,
          d = Join[d, Flatten@Table[, {nCol - over}]]
       ];
      GraphicsGrid[Partition[d, nCol], ImageSize -> {500, 400},Frame -> All]
      ];
   )
 ]

Answer 2

Here's a list of data of varying length num:

data[num_] := RandomReal[{-2, 2}, {num, 24, 2}];

and here's a function to grid this as closely as possible to a square:

gridgraph[p_List] := Module[{thres},
   thres = Floor@Sqrt@Length@p;
   GraphicsGrid@Partition[p, thres, thres, 1, Null]
   ] /; Length@p > 0

now

gridgraph[ListPlot /@ data[21]]

and

gridgraph[ListPlot /@ data[5]]

---EDIT(2)---

Your list of files depends on how you import. If they are located at a path, say, "C:/DIRECTORY/" and have extensions .dat then import them:

data = With[{$filedir = "C:/DIRECTORY/"},
 Import[$filedir <> #] & /@ 
  Select[Import[$filedir], StringMatchQ[#, "*dat"] &]]

This will be a list of eight lists (right?), some empty {} some consisting of pairs (right?).
Is the following what you need?

 Module[{plots},
 plots = (ListPlot /@ data) /. 
    ListPlot[{}] :> Null // Quiet; 
 GraphicsGrid[Partition[plots, 3, 3, 1, Null]]]