Limiting sliders dynamically

Question

My goal is to implement the three things below.

(i) Number of white balls(w ) and red balls(r) are constrained to be 2 ~ 29.

(ii)Total number(n) of balls is w+r and it shoud not exceed 30.

(iii)sampleSize is constrained to be at least 1 and at most n-1.

My code is as below;

Manipulate[n = w + r;  
 If[2 <= n <= 30, 
  Grid[{{"w", "r", "n=w+r", "sampleSize=n-1"}, {w, r, n, sampleSize}},
    Frame -> All], "not adjustable, w+r lager than 30"], {{w, 1}, 1, 
  29, 1}, {{r, 1}, 1, 29, 1}, {sampleSize, 1, n - 1, 1}, 
 ControlPlacement -> Left]

There are two problem to my code.How to improve?

1. My sampleSize was exceeding n-1 as below, violating (iii).

2. To implement (ii), is there a way to limit the maximum of w and r sliders so that w+r is always less than 29 whenever moving the w or r sliders? (I have used message to appear as below using If[] function to implement (ii), but I think there must be another way)

Answer 1

$Version

(* "13.3.1 for Mac OS X ARM (64-bit) (July 24, 2023)" *)

Clear["Global`*"]

Manipulate[
 n = w + r;
 sampleSize = Min[sampleSize, n - 1];
 If[n <= 30,
  Grid[{
    {" w ", " r ", "n\[ThinSpace]=\[ThinSpace]w+r", "sample size"},
    {w, r, n, sampleSize}},
   Frame -> All],
  "not adjustable, w+r larger than 30"],
 {{w, 10}, 1, 30, 1, Appearance -> "Labeled"},
 {{r, 10}, 1, 30 - w, 1, Appearance -> "Labeled"},
 {{sampleSize, 5, "sample size"}, 1, w + r - 1, 1,
  Appearance -> "Labeled"},
 ControlPlacement -> Left]

Answer 2

You can use a Slider with a custom control function for this kind of thing:

Manipulate[
 noCells = Min[sampleSize, w];
 If[2 <= n <= 30, 
  Grid[{{"w", "r", "n=w+r", "sampleSize=n-1"}, {w, r, n, sampleSize}},
    Frame -> All], "not adjustable, w+r lager than 30"],
 Grid[{
   {Slider[
     Dynamic[w,
      Function[
       w = #;
       n = w + r; 
       If[n > 30,
        r = 30 -  w;
        n = w + r
        ]
       ]
      ],
     {1, 29, 1}
     ]
    },
   {
    Slider[
     Dynamic[r,
      Function[
       r = #;
       n = w + r; 
       If[n > 30,
        w = 30 -  r;
        n = w + r
        ]
       ]
      ],
     {1, 29, 1}
     ]
    },
   {Slider[Dynamic[sampleSize], Dynamic[{1, n - 1, 1}]]}
   }
  ],
 Initialization :> (
   w = 1;
   r = 1;
   n = w + r;
   sampleSize = 1
   )
 ]