Modifying callout marker

Question

I want to remove the blue circles that appear as callout markers. How can I do that?

A = LogLogPlot[(x^5 - x^4 + x), {x, 0, 10}, PlotStyle -> Red];
Show[A, ListLogLogPlot[{{Callout[{2.5, 100}, Style["Test"], Above,LabelStyle -> {10, Bold, Blue}]}}]]

Is it also possible to change the color of blue circle, for example, one to red and the other to green?

Answer 1

Clear["Global`*"]

f[x_] = x^5 - x^4 + x;

A = LogLogPlot[f[x], {x, 0, 10}, PlotStyle -> Red];

To color each dot separately, make each Callout a separate list and use PlotStyle to specify their color. Likewise, using PlotStyle -> Opacity[0] will eliminate the dots (make them fully transparent).

Show[A,
 ListLogLogPlot[{
   {Callout[{2.5, f[2.5]}, Style["Test-1"], Above, 
     LabelStyle -> {10, Bold, Blue},
     Background -> Opacity[0]]},
   {Callout[{0.5, f[0.5]}, Style["Test-2"], Above, 
     LabelStyle -> {10, Bold, Blue}]}},
  PlotStyle -> {Red, Green}]]

Answer 2

The code you have doesn't generate that image, but I can hazard a guess. The blue circles are the output of the ListLogLogPlot command, not the Callout which consists of the line and the label. You can use CalloutStyle as an option to Callout to change the color of the line but it would not change the color of the blue circle in your case.

You could use the PlotStyle argument of ListLogLogPlot or modify your Callout like

ListPlot @ {Callout[
  Style[{2.5, 100}, Green], 
  Style["Test", FontSize -> 14, Bold, Blue], 
  Above, 
  CalloutStyle -> Orange
]}

to style each element individually.

Answer 3

You do not need a separate plot only for the callout. You can do this with a single plot:

LogLogPlot[Callout[(x^5 - x^4 + x), "Test", {2.5, 100}], {x, 0, 10}, 
 PlotStyle -> Red]