Asymptotic integral computation takes too long

Question

I am trying to understand how grows the function $k\mapsto\int_{0}^{\infty} \left({1 - \left(1 - \exp(-t/k)\right)^k}\right)dt$ for $k\to\infty$, and I expect a result asymptotically equal to $k\log(k)$. However, the following command, takes too much time:

Series[Integrate[1 - (1 - Exp[-t/k])^k, {t,0,\[Infinity]}],{k,\[Infinity],3}]

---

Question: Should I modify something in the command?

Answer 1

The short answer is that this integral is equal to k*HarmonicNumber[k] and therefore the expansion is given by

Series[k*HarmonicNumber[k],{k,Infinity,3}]
(* (EulerGamma+Log[k]) k+1/2-1/(12 k)+1/(120 k^3)+O[1/k]^4 *)

To derive this, I did a little bit of manual work: I made the substitution $1-e^{-t/k} = s$ which transforms OP's integral to the following integral, which Mathematica evaluates:

k*Integrate[(1-s^k)/(1-s),{s,0,1},GenerateConditions->False]
(* k HarmonicNumber[k] *)

Here is code to check the claim directly in some examples:

Table[FullSimplify[
   Integrate[1-(1-Exp[-t/k])^k,{t,0,Infinity}]==k*HarmonicNumber[k]],
 {k,{1/2,1,4,100/3}}]
(* {True,True,True,True} *)

Answer 2

A different approach for the same result as user293787 obtained

Clear["Global`*"]

f[k_] := Integrate[1 - (1 - Exp[-t/k])^k, {t, 0, ∞}]

Evaluate f for several positive integers

seq = f /@ Range[10]

(* {1, 3, 11/2, 25/3, 137/12, 147/10, 363/20, 761/35, 
  7129/280, 7381/252} *)

Use FindSequenceFunction to generalize from the sequence

f2[k_] = FindSequenceFunction[seq, k] // FullSimplify

(* k HarmonicNumber[k] *)

Compare with numeric evaluation of the integral

f3[k_?NumericQ] :=
 NIntegrate[1 - (1 - Exp[-t/k])^k, {t, 0, ∞}]

Plot[{k*Log[k], f2[k], f3[k]}, {k, 0, 1000},
 PlotStyle -> {Automatic, Automatic, {Red, Dashed}},
 PlotLegends -> Placed["Expressions", {.3, .7}]]