Plotting a function between its first roots

Question

Suppose that I have a continuous function $f: [-1,1] \to \mathbb{R}$, such that $f(0) =1$. We denote with $f_+$ the function that coincides with $f$ between its first non-positive and positive roots, and vanish (i.e. it it set equal to zero) everywhere else.

1. Is there some simple way to plot $f_+$ in Mathematica without having to determine numerically the roots of $f$?

2. Is there some simple way to integrate numerically $f_+$ over [-1,1]?

(f can be any continuous function, take for example f(x) = sin(10x) if you wish)

UPDATE: added one further question

Answer 1

Edit

Manipulate[Module[{f, roots, a, b, f1, int},
  f[x_, c_] = Sin[10 (x + c *\[Pi]/20)];
  roots = SplitBy[NSolveValues[{f[x, c] == 0, -1 <= x <= 1}, x], Sign];
  a = roots[[1, -1]];
  b = roots[[2, 1]];
  f1[x_, c_] = Piecewise[{{f[x, c], a <= x <= b}}, 0];
  int = NIntegrate[f1[x, c], {x, a, b}];
  Plot[{f[x, c], f1[x, c]}, {x, -1, 1}, 
   PlotStyle -> {Blue, Directive[Red, AbsoluteThickness[5]]}, 
   PlotLabel -> 
    Style[Framed[ToString[int]], 16, Blue, 
     Background -> Lighter[Yellow]]]], {c, -2, 2}]

Original

Clear[f,roots,a,b,f1];
f[x_] = Sin[10 (x + π/20)];
roots = SplitBy[NSolveValues[{f[x] == 0, -1 <= x <= 1}, x], Sign]
a = roots[[1, -1]]
b = roots[[2, 1]]
f1[x_] = Piecewise[{{f[x], a <= x <= b}}, 0];
Plot[{f[x], f1[x]}, {x, -1, 1}, 
 PlotStyle -> {Blue, Directive[Red, AbsoluteThickness[5]]}]
NIntegrate[f1[x], {x, a, b}]

Answer 2

Try RegionFunction inside Plot-command:

f = Function[x, -3 (x + 1/2) (x - 1/3) (x + 2)];
(* examplary funtion*)
Plot[f[x], {x, -1, 1}, RegionFunction -> Function[x, f[x] >=  0]]