How to add random point size to this distribution of 3d points?

Question

The code below creates a random distribution of points in 3D. Currently, the points have a random size, and the size is the same for all points. I need the points to get individually a random size, not the same for all points. How can I modify that code to do that? Please, the solution should work with old versions of Mathematica (I'm still using version 7.0 since my computer is very old). The colors could be random too, but I want to concentrate on the size first.

points3D[p_, q_, r_] := Module[{dat = RandomReal[{-1, 1}, {p, 3}]},
Do[AppendTo[dat, r RandomReal[{-1, 1}, 3] + RandomChoice[dat]], {i, q}]; dat
]

graph3D[p_, q_, r_] := Graphics3D[{RGBColor[{0.5, 0.4, 1.0, 0.4}], PointSize[RandomReal[{0.004, 0.01}]], Point[points3D[p, q, r]]}]

view[p_, q_, r_] := Show[{graph3D[p, q, r]},
    PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}},
    Boxed -> True,
    Background -> Black,
    ImageSize -> {700, 700},
    SphericalRegion -> True,
    Method -> {"RotationControl" -> "Globe"}
]

view[200, 5000, 0.1]

Preview of what this code is doing:

As you can notice on this picture, the points are all having the same size. I need them to get different random sizes.

Answer 1

getPts[n_, noise_] := 
 Module[{dat = RandomReal[{-1, 1}, {20, 3}]}, 
  Do[AppendTo[dat, noise RandomReal[{-1, 1}, 3] + RandomChoice[dat]], 
   n]; {PointSize[RandomReal[{0.003, 0.006}]], Point[#]} & /@ dat] 

Manipulate[
 Graphics3D[getPts[n, noise], 
  PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}], {{noise, 0.1}, 0, 
  0.4}, {{n, 1000}, 100, 5000}]

Answer 2

You might get better performance if you avoid the Module and Do loop:

points3D[locusCount_, cloudPointCount_, cloudRadius_] :=
  With[
    {locii = RandomReal[{-1, 1}, {locusCount, 3}]},
    randomCloudPoint[cloudRadius] /@ RandomChoice[locii, cloudPointCount]]

We determine the cloud "centers" or "locii" and then generate a random sample of them which we will then map our "fuzzing" function over. I introduced a function randomCloudPoint for this:

randomCloudPoint[radius_][locus_] := locus + RandomReal[{-radius, radius}, 3]

This gives a uniform distribution. You could use different distributions (not sure what's available in your version):

randomCloudPoint[radius_][locus_] := 
  locus + RandomVariate[NormalDistribution[0, radius/3], 3]

I used SubValues to make the mapping part simpler.

Now, as has previously been mentioned/demonstrated, you need to come up with a style for each point. I put this into another function:

randomPointStyle[ptSizeRange_, baseColor_, colorRange_][pt_] := 
  {PointSize[RandomReal[ptSizeRange]], 
   Darker[baseColor, RandomReal[{-colorRange, colorRange}]],
   Point[pt]}

There would be other ways to randomize the color.

The new graph3D looks like this:

graph3D[p_, q_, r_] := 
  Graphics3D[randomPointStyle[{.001, .01}, RGBColor[{0.5, 0.4, 1.0, 0.8}], .5] /@ points3D[p, q, r]]

(Didn't rename the arguments this time.) I changed the opacity a bit so the color variation was more obvious.

Here's a Manipulate:

Manipulate[
  view[locusCount, totalCount, cloudRadius], 
  {{locusCount, 20}, 1, 200, 1}, 
  {{totalCount, 500}, 1, 5000, 1}, 
  {{cloudRadius, .1}, .01, .5}]

(I didn't change view, but it would depend on the new functions above.)