Divide two 2D arrays element wise

Question

I have two 2D list

list1 = {{x,a1},{y,a2},{z,a3}}
list2 = {{x,b1},{y,b2},{z,b3}}

I want a list that divides only the second element of each element of the 2D array.

list3 = {{x,a1/b1},{y,a2/b2},{z,a3/b3}}

I know how to do this using a loop, but I want to know is there an elegant way using mathematica?

Answer 1

list3 = list1;
list3[[All, 2]] = list3[[All, 2]]/list2[[All, 2]];
list3

{{x, a1/b1}, {y, a2/b2}, {z, a3/b3}}

Also

list1 / Thread[{1, list2[[All, 2]]}]

{{x, a1/b1}, {y, a2/b2}, {z, a3/b3}}

and

SubsetMap[# / list2[[All, 2]]&, list1, {All, 2}]

{{x, a1/b1}, {y, a2/b2}, {z, a3/b3}}

Answer 2

A few more possibilities

a = {{x, a1}, {y, a2}, {z, a3}};

b = {{x, b1}, {y, b2}, {z, b3}};

Using SequenceCases with Riffle"

SequenceCases[Riffle[a, b], {a_, b_} :> {a[[1]], a[[2]] / b[[2]]}]

Using Cases with Transpose

Cases[Transpose[{a, b}], {a_, b_} :> {a[[1]], a[[2]] / b[[2]]}]

Using GroupBy

GroupBy[Join[a, b], First -> Last, Apply @ Divide]

Using Merge and MapApply (new in 13.1)

Merge[Apply @ Divide] @ MapApply[Rule] @ Join[a, b]

Association to List

KeyValueMap[List][%]

Answer 3

a = {{x, a1}, {y, a2}, {z, a3}};

b = {{x, b1}, {y, b2}, {z, b3}};

---

Using GatherBy and Replace at level 1:

rule = {{a__}, {b__}} :> {First@{a}, Divide @@ Last /@ {{a}, {b}}};

Replace[GatherBy[Join @@ {a, b}, First], rule, {1}]

{{x, a1/b1}, {y, a2/b2}, {z, a3/b3}}