Filling in LogLogPlot

Question

I have a function firsttempinterp[x] that I plot using LogLogPlot. I used Filling to fill a region with gray color, however, using PlotRangePadding does not cover the entire region I want. The region is above the curve until the y-axis to the left. Any guide on how to resolve this?

temp = {0.1, 0.1355, 0.5, 10};
firsttime = {0.21707, 0.23616, 0.44440, 6.47129};
firsttempdata = Transpose[{firsttime, temp}];
firsttempinterp = 
  Interpolation[
    firsttempdata, 
    InterpolationOrder -> 2, 
    Method -> "Spline"
  ]

LogLogPlot[{
  If[x < 0.23616 + 3 2.361387, firsttempinterp[x - 3 2.361387] + 3 1.355, None],
  If[x > 0.23616 + 3 2.361387, firsttempinterp[x - 3 2.361387] + 3 1.355, None]},
  {x, 0, 17}, 
  Frame -> True,
  FrameStyle -> Directive[Black, 20],
  PlotStyle -> {{Dashed, Black, Thick}, {Black, Thick}},
  PlotRange -> {All, {0.09, 10.5}}, 
  PlotRangePadding -> 0, 
  Filling -> {
     1 -> {Top, {Directive[Opacity[0.3], Gray]}},
     2 -> {Top, {Directive[Opacity[0.3], Gray]}}
  },
  ImageSize -> Large
]

Answer 1

LogLogPlot[Max[.09, firsttempinterp[x - 3 2.361387] + 3 1.355], {x, 0, 17}, 
 Frame -> True, FrameStyle -> Directive[Black, 20], 
 PlotStyle -> Directive[Thick, Black], 
 PlotRange -> {All, {0.09, 10.5}}, PlotRangePadding -> 0, 
 Filling -> Top,
 FillingStyle -> Directive[Opacity[0.3], Gray], 
 ImageSize -> Large, 
 MeshFunctions -> {#2 &}, 
 Mesh -> {{.09, 3 1.355}}, 
 MeshStyle -> None,
 MeshShading -> {None, Dashed, Dashing[{}]}, 
 PlotPoints -> 200, MaxRecursion -> 7]

Answer 2

With your definitions, add a gray background to the whole plot to represent your desired filling, then use an actual filling directive, using opaque white, to fill the part under the curve that should look "unfilled". The changes in your code are highlighted below between empty lines:

LogLogPlot[{
  If[x < 0.23616 + 3 2.361387, firsttempinterp[x - 3 2.361387] + 3 1.355, None],
  If[x > 0.23616 + 3 2.361387, firsttempinterp[x - 3 2.361387] + 3 1.355, None]},
  {x, 0, 17}, 
  Frame -> True,
  FrameStyle -> Directive[Black, 20],
  PlotStyle -> {{Dashed, Black, Thick}, {Black, Thick}},
  PlotRange -> {All, {0.09, 10.5}}, 
  PlotRangePadding -> 0, 

  Filling -> Axis, FillingStyle -> White,
  Prolog -> {
    Opacity[0.3, Gray],
    Rectangle[Scaled[{0, 0}], Scaled[{1, 1}]]
  },

  ImageSize -> Large
]

Answer 3

Add a fake function:

Exp[x - 1.2] == 100

to your existing plot and adjust the constant as you see fit.

LogLogPlot[
 {If[x < 0.23616 + 3 2.361387,
   firsttempinterp[x - 3 2.361387] + 3 1.355, None],
  If[x > 0.23616 + 3 2.361387,
   firsttempinterp[x - 3 2.361387] + 3 1.355, None],
  Exp[x - 1.2] == 100
  }
 , {x, 0, 17}
 , Frame -> True
 , FrameStyle -> Directive[Black, 20]
 , PlotStyle -> {
   {Dashed, Black, Thick}
   , {Black, Thick}
   , {Dotted, Thin, Red}
   }
 , PlotRange -> {{0.1, 12}, {0.09, 10.5}}
 , PlotRangePadding -> 0
 , Filling -> {
   1 -> {Top, {Directive[Opacity[0.3], Gray]}}
   , 2 -> {Top, {Directive[Opacity[0.3], Blue]}}
   , 3 -> {Top, {Directive[Opacity[0.3], Pink]}}
   }
 , ImageSize -> Large,
 AspectRatio -> 0.75
 ]

I am showing the three colored regions, that you can revert to Gray.