Difference of old Graphics`Graphics3D`ListSurfacePlot3D and the current ListSurfacePlot3D

Question

Consider the following example data which creates the lines of a cylinder

data=Table[{Cos[phi],Sin[phi],z},{phi,0,2Pi,.1},{z,0,1,.1}];
Graphics3D[{RandomChoice[ColorData[3,"ColorList"]],Line[#]}&/@data]

The coloring indicates the structure of data which is a list of lines where with lines I mean a list of {x,y,z} coordinates. Therefore, data is of dimension {63, 11, 3}: 63 lines where each line as 11 points.

With the legacy package of older Mathematica versions it was now possible to create the surface of the cylinder by

Needs ["Graphics` Graphics3D `"]
ListSurfacePlot3D[data]

If you look on the usage of the built-in ListSurfacePlot3D function you see that it can only take a list of 3D points and not such a structured tensor as data. When you then try it anyway, you get a surprising result:

ListSurfacePlot3D[data]

Question: is it possible to create the surface of the cylinder like the old version of ListSurfacePlot3D did?

On this simple examples, a call to

ListSurfacePlot3D[Flatten[data, 1]]

helps. Unfortunately, for my original data here, this doesn't work. You can recreate the error by shearing the cylinder data

data = Table[
   {Cos[phi] + 2 z, z, Sin[phi] + z}, {phi, 0, 2 Pi, .1}, {z, -2, 
    2, .1}];
Graphics3D[{RandomChoice[ColorData[3, "ColorList"]], Line[#]} & /@ 
   data]
ListSurfacePlot3D[Flatten[data, 1]]

and then you get

Answer 1

The first thing I tried was to Flatten your data, so that it is a flat list of 3D coordinates. When you take your simple cylinder example and apply for instance a shearing transformation, you see, that you cannot rely on what ListSurfacePlot3D is doing.

Not only that it does not reconstruct your whole cylinder points, furthermore it gets really messy when the shearing kicks in:

With[{data = Flatten[Table[
     {Cos[phi], Sin[phi], z}, {phi, 0, 2 Pi, .1}, {z, -1, 1, .1}], 1]},

 Manipulate[
  Show[
     ListSurfacePlot3D[#],
     Graphics3D[{AbsolutePointSize[1], Red, Point[#]}],
     PlotRange -> {{-2, 2}, {-2, 2}, {-2, 2}}, PlotRangePadding -> .5
     ] &[
   ShearingTransform[phi, {1, 0, 0}, {0, 0, 1}][data]],
  {phi, 0, Pi/2}]
 ]

If you want to have the behavior of the old ListSurfacePlot3D back, you could investigate in the AddOns/LegacyPackages/Graphics directory of a version 8 installation and extract the important code:

MakePolygons[vl_List] := 
 Module[{l = vl, l1 = Map[RotateLeft, vl], mesh}, 
  mesh = {l, l1, RotateLeft[l1], RotateLeft[l]};
  mesh = Map[Drop[#, -1] &, mesh, {1}];
  mesh = Map[Drop[#, -1] &, mesh, {2}];
  Polygon /@ Transpose[Map[Flatten[#, 1] &, mesh]]]

ListSurfacePlot3DOld[data_, opts : OptionsPattern[]] := 
 Graphics3D[MakePolygons[data], 
  Evaluate[FilterRules[{opts}, Options[ListSurfacePlot3D]]]]

And now, everything should work as expected

ListSurfacePlot3DOld[data, Axes -> False]

Answer 2

I can't really blame the OP. After all, the docs here so glibly recommend that one now do ListSurfacePlot3D[Flatten[pts, 1]] where one once needed to do ListSurfacePlot3D[pts].

We could, as halirutan did in his answer, grab the old routine from the package Graphics`Graphics3D` and just use it again in the new Mathematica. Or, we could exploit the fact that Mathematica now has GraphicsComplex[], which lets us write a modernized version of Roman Maeder's MakePolygons[]:

MakePolygons[vl_] := Module[{dims = Most[Dimensions[vl]]}, 
  GraphicsComplex[Apply[Join, vl], Polygon[Flatten[Apply[Join[#1, Reverse[#2]] &, 
                  Partition[Partition[Range[Times @@ dims], Last[dims]], {2, 2}, {1, 1}],
                        {2}], 1]]]] /; ArrayQ[vl, 3]

which we can now use to turn the array of points into a nice pile of Polygon[]s:

data = Table[N[{2 z + Cos[φ], z, z + Sin[φ]}], {φ, 0, 2 π, π/30}, {z, -2, 2, 1/10}];

Graphics3D[MakePolygons[data]]

One does lose out on the options supported by the new ListSurfacePlot3D[] like coloring or texturing, but this might be offset by the comfort of seeing Mathematica dutifully render the mesh you expected and were supposed to see.