Setting nested optional argument with a default when unpacking from a given Head

Question

I have a head that holds a single argument, and I want to unpack the value inside it while also assigning a symbol to the value itself, for example:

f[y:g[x_]] := {y, x};

f[g[4]] (* == {g[4], 4} *)

This works fine, but when I want to give it a default argument, x does not bind to the inner value:

f[y:g[x_]:g[10]] := {y, x};

f[] (* == {g[10]}, rather than {g[10], 10} *)

How do I make x bind to the inside of the default value?

This is my real-world example:

squareLattice = lattice[{n1 -> {1, 0}, n2 -> {0, 1}}];

doRandomWalk[n_Integer, l:lattice[basis_]:squareLattice] :=
  With[{basisSymbols = First /@ basis},
   Echo[basis]; 
   randomWalk[
    Accumulate@
     Table[RandomChoice[{1, -1}] RandomChoice[basisSymbols], n],
    l]];

When I evaluate using the default argument: doRandomWalk[100], I get a message from Echo, as basis is not bound to anything

Thank you for any help!

Answer 1

Well, here's one way to do it:

f[y : g[x_] : g[10]] := {y, Replace[Unevaluated[x], Sequence[] :> First[y]] }

f[]
(*{g[10], 10}*)

f[g[20]]
(*{g[20], 20}*)

Note that x_ can't bind to the default, because there's no requierment that the default match the pattern:

In[83]:= f[y:g[x_]:{1, 2, 3}] := {y, Replace[Unevaluated[x], Sequence[] :> First[y]]}

f[]
(*{{1, 2, 3}, 1}*)

Answer 2

This method doesn't work in recent versions. In/Out from version 10.1 below.

---

For the short example given you could specify it like this:

f[y : g[x_: 10] : g[10]] := {y, x};

f[]

{g[10], 10}

I just realized this introduces a behavior you probably don't want:

f[g[]]

{g[], 10}

The same (flawed) method applied to the longer example:

squareLattice = lattice[{n1 -> {1, 0}, n2 -> {0, 1}}];

With[{def = squareLattice},
  doRandomWalk[n_Integer, l : lattice[basis_: def[[1]]] : def] := {n, l, basis}
 ]

doRandomWalk[5]

{5, lattice[{n1 -> {1, 0}, n2 -> {0, 1}}], {n1 -> {1, 0}, n2 -> {0, 1}}}