ReplaceList doesn't apply rules down to subparts

Question

Somewhat related to a previous question, I'm experimenting with ReplaceList to get the list of all possible transformations we can obtain by applying a rule to an expression. But I don't manage to make it work as expected:

expr := 1+Cos[ω t - π/4 + 3π/4]
rule := Cos[a_ + b_] -> X[a,b]
ReplaceList[expr,{ rule }]

I expected the result:

>     { 1+X[ω t - π/4, 3π/4], 1+X[ω t, -π/4 + 3π/4] }

But instead, I obtain:

{}

Why is Mathematica unable to apply rule on expr? How should I fix my code to obtain the expected result?

---

As an extra requirement, I missed the fact that ReplaceAll like Replace "does not map down to subparts".

I'm probably looking for a mix between ReplaceList and Cases (?)

---

As per comment, to avoid Mathematica to rewrite the expression as a sinus, I tried wrapping it inside various Hold* functions--in no case, the rule is applied.

expr := Hold[1+Cos[ω t - π/4 + 3π/4]]

expr := HoldForm[1+Cos[ω t - π/4 + 3π/4]]

expr := HoldComplete[1+Cos[ω t - π/4 + 3π/4]]

Answer 1

As discussed in comments, you have to somehow prevent MMA from rewriting your Cos expression, which you can accomplish with a Hold function. I am still not sure that I understand the intended outcome, but I wonder if this is what you are after:

Clear[expr, rule]
expr = HoldForm@Cos[ω t - π/4 + 3 π/4]
rule = HoldForm@Cos[a_ + b_] :> X[a, b]
ReplaceList[expr, rule]

(* Out: 
{X[t ω, π/2], X[-(π/4), (3 π)/4 + t ω], 
 X[(3 π)/4, -(π/4) + t ω], 
 X[-(π/4) + t ω, (3 π)/4], 
 X[(3 π)/4 + t ω, -(π/4)], X[π/2, t ω]}
*)

Answer 2

Try this instead

expr := Hold[Cos[ω t - π/4 + 3 π/4]]
rule := Cos[a_ + b_] :> X[a, b]
ReleaseHold[ReplaceAll[expr, {rule}]]

X[t ω, π/2]

In reply to the comment

expr := Hold[Cos[ω t - π/4 + 3 π/4]]
rule := Cos[a_] :> (a /. List -> X)
ReleaseHold[ReplaceAll[expr /. Plus -> List, {rule}]]

X[t ω, -(π/4), (3 π)/4]

I'm sure there is a simpler way.

Answer 3

You may be trying to solve the wrong problem. It is better to define a rule that applies to all the forms in which your expression might appear. For example

expr = Cos[ω t - π/4 + (3 π)/4]
(* -Sin[t ω] *)

rule = {Cos[a_ + b_.] -> X[a, b], Sin[a_ + b_.] -> X[a, -(π/2) + b]};

expr /. rule
(* -X[t ω, -(π/2)] *)

Answer 4

Perhaps this approach is more in keeping with your coding style.

expr = Inactivate[1 + Cos[ω t - π/4 + 3 π/4], Cos]
rule = Inactive[Cos][Plus[args__]] -> X[args]
ReplaceAll[expr, rule]

1 + X[π/2 + t ω]

Notes

• Personally, I prefer the short form

  expr /. rule
  

  to using ReplaceAll.
• The revised rule you see above was written after I inspected

  expr // FullForm
  

  Plus[1, Inactive[Cos][Plus[Times[Rational[1, 2], Pi], Times[t, ω]]]]