Why is ReplaceAll behaving like this?

Question

I'm learning to use the ReplaceAll function and I found the behavior of which is quite confusing.

---

For

Sqrt[f[x, y]] /. f[___] -> u

Mathematica returns

Sqrt[u]

However, if I replace f with Plus, i.e.

Sqrt[Plus[x, y]] /. Plus[___] -> u

instead of returning Sqrt[u], Mathematica gives

u

---

For

a*Sqrt[x] /. Sqrt[_] -> u

Mathematica gives

a u

However, if the input is

a/Sqrt[x] /. Sqrt[_] -> u

Instead of returing a/u, Mathematica returns

a/Sqrt[x]

I'm really confused. Can anybody shed some light on the behavior of this function?

Answer 1

Case #1

Observe:

"anything" /. Plus[___] -> "match"

"match"

This is because Plus[___] evaluates to ___, and ___ matches anything. You can use HoldPattern:

Sqrt[Plus[x, y]] /. HoldPattern[Plus[___]] -> u

Sqrt[u]

For this particular case you could also use the form _Plus, which matches any expression with head Plus but not Plus itself:

Sqrt[Plus[x, y]] /. _Plus -> u

Sqrt[u]

Case #2

You must understand that pattern matching is done on something close to the FullForm of an expression, rather than the StandardForm output you normally see. Let's look at your second problematic expression:

a/Sqrt[x] // FullForm

Times[a,Power[x,Rational[-1,2]]]

As you can see, Sqrt is nowhere to be found.

You could prevent the evaluation of Sqrt on both the left-hand and right-hand sides:

Unevaluated[a/Sqrt[x]] /. HoldPattern[Sqrt[_]] -> u

a/u

If you need to match for things that appear as Radicals in StandardForm you can use the methods described here. An application of that might look like this:

ToBoxes[a/Sqrt[x]] /. _SqrtBox -> u // ToExpression

a/u