Using Images for Points in ListPlot

Question

I'm using ListPlot to label a sequence of ordered pairs in $[-1,1] \times [-1,1]$:

Question: How can I make these points show up as images (from the web, etc) instead of as blue dots? I'd like to keep the "Callout" labels if possible, but it's not strictly necessary.

Answer 1

Using PlotMarkers as @C.E. suggested and images from @kglr

images = Rasterize[ExampleData[{"TestImage", #}], 
    RasterSize -> 200, ImageSize -> 30]&/@ {"Lena","Apples"};

ListPlot[{{Callout[{0.8, 0.8}, "A", Above]}, {Callout[{-0.8, -0.8}, 
    "B", Above]}}, Frame -> True, PlotMarkers -> images, 
 PlotRange -> {{-1.25, 1.25}, {-1.25, 1.25}}]

Answer 2

data = {{1, 1}, {4, 4}};
labels = {"A","B"};
images = Rasterize[ExampleData[{"TestImage", #}], 
    RasterSize -> 200, ImageSize -> 30]&/@ {"Lena","Apples"};

Using images as plot markers (as in Rohit's answer) is the most straightforward approach. Here are a few additional ways:

ListPlot with nested Callouts:

You can use the image as one of multiple call-outs for each data point:

data2 = MapThread[Callout[Callout[#, #3, Automatic, 1, 
      LeaderSize -> {{40, 45 Degree, 20}, 20}, Appearance -> "Leader"], #2, Center] &, 
    {data, images, labels}];

ListPlot[data2,  Frame -> True, Axes -> False, PlotRangePadding -> 2]

ListPlot + Callout + Labeled:

You can use Labeled to inject the image as a label:

data3 = MapThread[{Callout[Labeled[#, #2, Center], #3, Automatic, 1, 
        LeaderSize -> {{40, 45 Degree, 20}, 20}, Appearance -> "Leader"]} &, 
     {data, images, labels}];

ListPlot[data3,  Frame -> True, Axes -> False, PlotRangePadding -> 2]

BubbleChart + ChartElements:

BubbleChart[Append[#, 1]& /@ data,
  ChartElements -> images,
  ChartLabels -> Callout[labels, Above], 
  PlotRangePadding -> 1]