On double summation with Mathematica

Question

Today I wanted to evaluate this sum using Mathematica:

$$f(a,b):=\sum_{(k,l)\in\mathbb{Z}^2,\ l\ne0}\frac{1}{(2 i k a \pi + l b) (2 i (k - l) a \pi + l b)}$$

Sum[ If[ l == 0, 0, 
1/((2 I k a \[Pi] + l b) (2 I (k - l) a \[Pi] + l b))
], {l, -Infinity, Infinity}, {k, -Infinity, Infinity}]    

And the result I am given is 0.

However, if I give specific values to $a, b$ and then evaluate the sum numerically, I obtain values different to $0$, as, for $a= 30, b=2$:

Sum[If[l == 0, 0, 
N[1/((2 I k 30 \[Pi] + l 2) (2 I (k - l) 30 \[Pi] + l 2))]]
, {l, -1000, 1000}, {k, -1000, 1000}]

Obtaining the output:

0.000137911 + 2.53623*10^-6 I

Plotting the sum with $b=2$:

Plot[Abs[Sum[
If[l == 0, 0, 
a^2/((2 I k a \[Pi] + l 2) (2 I (k - l) a \[Pi] + l 2))]
, {l, -70, 70}, {k, -70, 70}]], {a, 15, 100}]

Seems that $|f|=O(\frac{1}{a^2}), f \ne 0$.

What it wrong with the symbolic calculation?

Answer 1

Let us put a=1/(2*\[Pi]) and b=1 in order to work with a concrete series. Next, let us use n instead of yourl (The use of l is not convenient because of its similarity to the imaginary unit I and the unit 1.). True series are absolutely convergent series (see https://en.wikipedia.org/wiki/Series_(mathematics) ,especially the Absolute convergence section, as a first reading). Let us calculate (notice that the terms of the series are complex-valued)

FullSimplify[ComplexExpand[Abs[1/((I*k + n)*(I*(k - n) + n))]], 
 Assumptions -> k \[Element] Reals && n \[Element] Reals]

1/Sqrt[(k^2 + n^2) (k^2 - 2 k n + 2 n^2)]

The sum of 1/Sqrt[(k^2 + n^2) (k^2 - 2 k n + 2 n^2)] over all the integer values of k and all the integer values of n but zero can be split into two sums. Let us consider one of these

Sum[1/Sqrt[(k^2 + n^2) (k^2 - 2 k n + 2 n^2)], {n, 1, Infinity}, {k, -Infinity, Infinity}]

.Mathematica 11.3.0.0 returns it unevaluated on my comp. However, arguments similar to used in the integral test show that this sum is of the same quantity as the double improper integral

Integrate[1/Sqrt[(k^2 + n^2) (k^2 - 2 k n + 2 n^2)],{n,1,Infinity},{k,-Infinity,Infinity}]

See a typical plot

Plot3D[1/Sqrt[(k^2 + n^2) (k^2 - 2 k n + 2 n^2)], {k, 10, 11}, {n, 9,  12}]

to this end.

The above integral is divergent. This is clear if one switches to polar coordinates by (the r multiplier is the Jacobean)

1/Sqrt[(k^2 + n^2) (k^2 - 2 k n + 2 n^2)]*r /. {n -> r*Sin[\[Phi]], k -> r*Cos[\[Phi]]}//FullSimplify

$$\frac{\sqrt{2} r}{\sqrt{-r^4 (2 \sin (2 \phi )+\cos (2 \phi )-3)}} $$

Therefore, the sum of the series under consideration has no sense. Maybe, its sum exists as some generalized sum. In view of it the result

Sum[1/((I*k + n)*(I*(k - n) + n)), {n, 1, Infinity}, {k, -Infinity, Infinity}]

0

is not reliable, in particular, the sum may depend on the order of the terms. It should be noticed that

Sum[1/((I*k + n)*(I*(k - n) + n)),  {k, -Infinity,  Infinity},{n, 1, Infinity}]

returns unevaluated.