How can I replace a function? Something like f[x] /. f -> -g. ReplaceAll doesnt seem to work properly when there is a minus sign

Question

How can I replace a function with minus another function? This: Sin[x] /. Sin -> Cos works just fine. But this: Sin[x] /. Sin -> -Cos gives (-Cos)[x] and I cannot evaluate it, in this output x is not recongnized as the function's argument. Seems simple but I could not find a way to do this. Help, please!

Answer 1

Try

Sin[x] /. Sin[x] -> -Cos[x]

which gives you -Cos[x]

If you have a slightly more complicated problem like Sin[x] + Sin[y] and you want to replace both those Sin then this

Sin[x] + Sin[y] /. Sin[z_] :> -Cos[z]

will give you -Cos[x] - Cos[y]

Answer 2

I usually replace the f with a pure function this way:

Sin[x] /. Sin -> (-Cos[#] &)

It substitutes for all f, if there is more than one form of f in the expression

Sin[x] + Sin[x^2]/. Sin -> (-Cos[#] &)
(*  -Cos[x] - Cos[x^2]  *)

The same approach works if there are pure derivatives in the expression, such as when using a known solution to factor and reduce the order of a linear ODE (in the example below, $y= x$ is a solution, so factor $y = x \int u \,dx$ to get a first-order equation for $u$):

y''[x] + x^2 y'[x] - x y[x] == 0 /. {y -> (# Integrate[u[#], #] &)} // Simplify
(*  (2 + x^3) u[x] + x u'[x] == 0  *)

Answer 3

It is possible to force Mathematica handle head operations of this kind as follows:

Needs["GeneralUtilities`"];

Unprotect[Times];

(-h_?NumericFunctionQ)[arg__] := -h[arg];

Protect[Times];

Now:

Sin[x] /. Sin -> -Cos

-Cos[x]

Standard caveats of modifying built-ins apply.

Answer 4

The following works :

Sin[x] /. Sin[xx_] -> -Cos[xx]  

-Cos[x]

It is safer to use (if x is allready defined) :

Sin[x] /. Sin[xx_] :> -Cos[xx]   

The following seems to work too :

Sin[x] /. Sin -> Composition[Minus,Cos]  

though I have never used this latest form.