Cross-Rearranging parts of nested lists inside list of associations

Question

I have list of associations like this:

er={<|A->{d11,{"1b1","2b1","3a1"}},B->{d12,{"1a1","2a1","3b1"}},C->{d13,{"1c1","2c1","3c1"}}|>,
<|A->{d21,{"1b2","2b2","3a2"}},B->{d22,{"1a2","2a2","3b2"}},C->{d23,{"1c2","2c2","3c2"}}|>,
<|A->{d31,{"1b3","2b3","3a3"}},B->{d32,{"1a3","2a3","3b3"}},C->{d33,{"1c3","2c3","3c3"}}|>,
<|A->{d41,{"1a4","2a4","3a4"}},B->{d42,{"1b4","2b4","3b4"}},C->{d43,{"1c4","2c4","3c4"}}|>,
<|A->{d51,{"1a5","2a5","3a5"}},B->{d52,{"1b5","2b5","3b5"}},C->{d53,{"1c5","2c5","3c5"}}|>}

I want to swap data between rules A and B and to only on [[2]][[;; 2]]their parts/levels, eg. in A "1b1","2b1" should be "1a1","2a1", and in B "1a1", "2a1" should be "1b1","2b1",...and the same procedure for only next two associations, 3 in total). So, the resulting, corrected list of associations would be:

ok={<|A->{d11,{"1a1","2a1","3a1"}},B->{d12,{"1b1","2b1","3b1"}},C->{d13,{"1c1","2c1","3c1"}}|>,
<|A->{d21,{"1a2","2a2","3a2"}},B->{d22,{"1b2","2b2","3b2"}},C->{d23,{"1c2","2c2","3c2"}}|>,
<|A->{d31,{"1a3","2a3","3a3"}},B->{d32,{"1b3","2b3","3b3"}},C->{d33,{"1c3","2c3","3c3"}}|>,
<|A->{d41,{"1a4","2a4","3a4"}},B->{d42,{"1b4","2b4","3b4"}},C->{d43,{"1c4","2c4","3c4"}}|>,
<|A->{d51,{"1a5","2a5","3a5"}},B->{d52,{"1b5","2b5","3b5"}},C->{d53,{"1c5","2c5","3c5"}}|>}

Please help with composing procedure to rearrange wrong to correct associations.

EDIT: none of the values are fixed and are not known in advance, they are arbitrary numbers. as, bs and cs are used only for exposure and to avoid mess. Only keys (A, B C) are fixed and known in advance.

Answer 1

Association @* KeyValueMap[
  # -> (
    #2 /. s_String :> StringReplace[s, LetterCharacter :> ToLowerCase[ToString[#]]]
  ) &
] /@ er

Answer 2

Not the most elegant, but I believe this will do what you want:

Table[
 <|A -> {(A /. er[[i]])[[1]], 
    StringReplace[(A /. er[[i]])[[2]], "b" | "c" -> "a"]},
  B -> {(B /. er[[i]])[[1]], 
    StringReplace[(B /. er[[i]])[[2]], "a" | "c" -> "b"]},
  C -> {(C /. er[[i]])[[1]], 
    StringReplace[(C /. er[[i]])[[2]], "b" | "a" -> "c"]}|>, 
 {i, Length[er]}]

{<|A -> {d11, {"1a1", "2a1", "3a1"}}, 
  B -> {d12, {"1b1", "2b1", "3b1"}}, 
  C -> {d13, {"1c1", "2c1", "3c1"}}|>, <|A -> {d21, {"1a2", "2a2", 
     "3a2"}}, B -> {d22, {"1b2", "2b2", "3b2"}}, 
  C -> {d23, {"1c2", "2c2", "3c2"}}|>, <|A -> {d31, {"1a3", "2a3", 
     "3a3"}}, B -> {d32, {"1b3", "2b3", "3b3"}}, 
  C -> {d33, {"1c3", "2c3", "3c3"}}|>, <|A -> {d41, {"1a4", "2a4", 
     "3a4"}}, B -> {d42, {"1b4", "2b4", "3b4"}}, 
  C -> {d43, {"1c4", "2c4", "3c4"}}|>, <|A -> {d51, {"1a5", "2a5", 
     "3a5"}}, B -> {d52, {"1b5", "2b5", "3b5"}}, 
  C -> {d53, {"1c5", "2c5", "3c5"}}|>}

Answer 3

ok2 = er;
ok2[[;;3]] = ReplaceAll[er[[;;3]], Association[A -> {a_, b_ }, B -> {c_, d_}, rest___] :>
  Association[A -> {a, Append[Most@d, Last@b]}, B-> {c, Append[Most@b, Last@d]}, rest]];
ok2 == ok

True

Answer 4

Thanks for idea. I finally find the solution.

((Association @*({
Keys[#][[1]]->{#[A][[1]],#[B][[2]][[;;2]]~Join~#[A][[2]][[{3}]]},
Keys[#][[2]]->{#[B][[1]],#[A][[2]][[;;2]]~Join~#[B][[2]][[{3}]]},
Keys[#][[3]]->{#[C][[1]],#[C][[2]]}}&)/@#[[;;3]])~Join~#[[4;;]])&@er