Possible bug in integration involving $\cos (n \phi)$

Question

I wanted to verify the integral $\int\limits_0^{2\pi}\frac{d\phi}{(a^2+b^2)+(a^2-b^2)\cos(n\phi)}=\frac{\pi}{ab}$ (where $b>a>0$ and $n$ is a positive integer).

Individual values of $n$ work:

$Assumptions = {b > a > 0};

Integrate[1/((a^2 + b^2) + (a^2 - b^2) Cos[x]), {x, 0, 2Pi}]
*** Pi/(ab) *** 

Integrate[1/((a^2 + b^2) + (a^2 - b^2) Cos[2 x]), {x, 0, 2Pi}]
*** Pi/(ab) *** 

Integrate[1/((a^2 + b^2) + (a^2 - b^2) Cos[3 x]), {x, 0, 2Pi}]
*** Pi/(ab) ***

and so on.

But then, when I want to solve it for general $n$, I get:

$Assumptions = {b > a > 0, n \[Element] Integers, n >= 1};

Integrate[1/((a^2 + b^2) + (a^2 - b^2) Cos[n x]), {x, 0, 2 Pi}]]
*** Pi/(abn) ***

What is going on? (I'm using 11.0.1.0 on OSX.)

Answer 1

There are similar integrals with bugs, some of which have been fixed, such as Suspected bug in Integrate.

It seems that the branch cuts in the antiderivative are ignored, the antiderivative containing an ArcTan:

Integrate[1/((a^2 + b^2) + (a^2 - b^2) Cos[n x]), x]
(*  ArcTan[(b Tan[(n x)/2])/a]/(a b n)  *)

One way to get the desired result is to integrate over just one period and multiply:

n*Integrate[1/((a^2 + b^2) + (a^2 - b^2) Cos[n x]), {x, 0, 2 Pi/n}, 
  Assumptions -> {b > a > 0, n ∈ Integers, n >= 1}]
(*  π/(a b)  *)

It should be reported to WRI, so that they might try to fix it.