Labeling elements of a grid

Question

Let's create a simple $3 \times 3$ grid of images

img = ExampleData[{"TestImage", "Lena"}];
P0 = Show[GraphicsGrid[{{img, img, img}, {img, img, img}, {img, img, img}}]]

My question: Is there a quick and elegant way of adding labels (1), (2), ... , (9) at the upper right part of each image? The labels should be located outside the upper right part of each panel, like the following

EDIT

Obviously, the above is just a simple case. In my real situation I have a $4 \times 4$ grid containing 16 different images with different names. So the solution must not work only for the same image, repeated many times.

EDIT II

If I try

im0 = Import["Lena.jpg"];
imn0 = Labeled[im0, {Style["(1)", FontFamily -> "Helvetica", 12, Bold]}, {{Top, Right}}];
plot0 = Show[GraphicsGrid[{{imn0, imn0, imn0, imn0}, {imn0, imn0, imn0, 
 imn0}, {imn0, imn0, imn0, imn0}, {imn0, imn0, imn0, imn0}}]]

then I get

Why the labels are not shown properly?

Any suggestions?

Answer 1

GraphicsGrid[i = 0; 
 Map[Show[#, 
     Graphics[
      Inset[i++; Style[Text["(" <> ToString[i] <> ")"], 18, White], 
       Scaled[{.15, .9}]]]] &] /@ Table[img, {3}, {3}], 
 ImageSize -> 300]

---

Or maybe this is your after?

GraphicsGrid[i = 0;Map[Labeled[#, i++; 
     Style[Text["(" <> ToString[i] <> ")"], 
      Black], {{Right, Top}}] &] /@ Table[img, {3}, {3}]]

---

As your edit,maybe

GraphicsGrid[i = 0; Map[Labeled[#, i++; 
     Style[Text["(" <> ToString[i] <> ")"], Black], {{Top, Right}}, 
     ImageSize -> 100] &] /@ Table[img, {3}, {3}]]

Answer 2

In the following, I create a new graphics with PlotRange 0 to 1.2. I then use Inset to insert the image into the new graphics and specify that it should occupy the plot range 0 to 1. This means that I have a padding on the upper and right-hand side of the image of 0.2 plot range. That gives me space to put the text in.

img = ExampleData[{"TestImage", "Lena"}];

labeled[img_, label_] := Graphics[{
   Inset[img, {0, 0}, {0, 0}, {1, 1}],
   Text[Style[label, FontSize -> 12], {1.1, 1.1}]
   }, PlotRange -> {{0, 1.2}, {0, 1.2}}]

imgs = MapThread[
    labeled, {ConstantArray[img, 9], StringTemplate["(``)"] /@ Range[9]}
    ];

GraphicsGrid@Partition[imgs, 3]