How can I find the values that make a certain expression less than 0.5?

Question

I want a work program to print the values that make expr less than 0.5 when $R_n \in (0,1)$.

exp = 
  Subscript[R, 1] Subscript[R, 2] Subscript[R, 5] Subscript[R, 6] Subscript[R, 11] + 
  Subscript[R, 1] Subscript[R, 3] Subscript[R, 5] Subscript[R, 6] Subscript[R, 11] - 
  Subscript[R, 1] Subscript[R, 2] Subscript[R, 3] Subscript[R, 5] Subscript[R, 6] Subscript[R, 11] + 
  Subscript[R, 1] Subscript[R, 2] Subscript[R, 7] Subscript[R, 11]; 
variables = SortBy[Variables[exp], Last];
values = Array[Symbol["v" <> ToString[#]] &, Length @ Variables[exp]];

Manipulate[
  Evaluate[exp /. Thread[variables -> values] // Style[#, 24] &],
  Evaluate[
    ## & @@ 
      ({{#, .5, ToString[#2, TraditionalForm]}, 0, 1, Appearance -> "Labeled"}& 
        @@@ Transpose[{values, variables}])], 
  Alignment -> Center]

I want a program or device policewoman prints values in the equation that make expless than 0.5 and deliver in the form of a table. Such an image or in any other form while maintaining the condition

Make compensation per ten and percent values like....$0.nn$ when n=0,1,...,9

Answer 1

v = Variables[exp];
Prepend[N[
   Append[v, exp] /. 
    FindInstance[exp < 1/2 && 0 < # < 1 & /@ v , v , 20]], 
  Append[v, "exp"]] // MatrixForm

One way to restrict the results to even 10's is to round and then double check we still meet the criterea.

TableForm[
 Sort@Select[Join[#, {(exp /. Rule @@@ Transpose[{v, #}])}] & /@
    Union[
     Round[v /. 
       FindInstance[(exp /. Subscript[R, n_] :> Subscript[R, n]) < 
            1/2 &&
            0.05 < # < .95 & /@ v , v , 20], .1]] , Last[#] < .5 &], 
 TableHeadings -> {None, Join[v, {"exp"}]}]

Answer 2

exp = Subscript[R, 1] Subscript[R, 2] Subscript[R, 5] Subscript[R, 
     6] Subscript[R, 11] +
   Subscript[R, 1] Subscript[R, 3] Subscript[R, 5] Subscript[R, 
     6] Subscript[R, 11] -
   Subscript[R, 1] Subscript[R, 2] Subscript[R, 3] Subscript[R, 
     5] Subscript[R, 6] Subscript[R, 11] +
   Subscript[R, 1] Subscript[R, 2] Subscript[R, 7] Subscript[R, 11];

variables = exp // Variables // Sort;

Module[{expValue, varValues},
 With[{nbrOfResults = 15},
    Table[
      Catch[
       Do[
        If[(expValue = Round[
             exp /. Thread[
               variables -> (varValues =
                  Round[RandomReal[{0, 1}, Length[variables]], .1])],
             0.01]) < 1/2,
         Throw[{
            NumberForm[#, {3, 1}] & /@ varValues,
            NumberForm[expValue, {4, 2}]} //
           Flatten]],
        10000]],
      {nbrOfResults}] //
     SortBy[#, Last] &] //
   Prepend[#, {variables, "exp"} // Flatten] & //
  Grid[#, Frame -> All] &]