TogglerBar Problem

Question

Is it possible to save information from a toggler bar to a variable when a button is clicked?

Example:

I have a toggler bar with its buttons numbered, say 1–4. When I press on a the button showing 1, I would like to have 1 saved to variable x. When I press the button showing 2 is pressed, I would like 2 saved to variable y. And so on.

Answer 1

I think this does what you want. a is the control variable and x, y, and z are controlled by the togglers.

TogglerBar[
  Dynamic[a, (a = #; Clear[x, y, z]; ReleaseHold[#]) &],
  {Hold[x = 1] -> 1, Hold[y = 2] -> 2, Hold[z = 3] -> 3}
]

Dynamic[{x, y, z}]

If that does what you want here is a utility function to make using it easier.

SetAttributes[myToggles, HoldFirst]

myToggles[var_, val_] := myToggles[var, val, val]

myToggles[{var__Symbol}, val : {__}, lbl : {__}] :=
  Module[{a},
    TogglerBar[
      Dynamic[a, (a = #; Clear[var]; ReleaseHold[#]) &], 
      MapThread[
        Function[, Hold[# = #2] -> #3, HoldAll],
        Unevaluated @ {{var}, val, lbl}
      ]
    ]
  ]

Examples:

myToggles[{a, b, c}, {1, 2, 3}]
Dynamic[{a, b c}]

myToggles[{m, n, o}, {1, 2, 3}, {"one", "two", "three"}]
Dynamic[{m, n, o}]

Answer 2

If you are willing to use an indexed variable to track the buttons pressed on the bar, fairly simple code will work.

Clear[bar, b]
bF = (bar = #; Clear[b]; Evaluate[b /@ #] = #) &;
With[{nBtns = 5},
  Column[
    {TogglerBar[Dynamic[bar, bF], Range[nBtns]],
     Dynamic[b /@ Range[nBtns]]}]]