How can I control label output for a HorizontalGauge

Question

I am trying to build a HorizontalGauge control for use in a Manipulate. The gauge should enable the user to select a day of the month. The following code seems to work fine (with one exception, noted below):

 MyGauge :=
  HorizontalGauge[
    #1, #2,
    GaugeFrameStyle -> Gray,
    GaugeFaceStyle -> LightOrange,
    (*GaugeLabels\[Rule]Automatic,*)
    GaugeLabels -> Placed[#1, Above],
    ScaleDivisions -> {8, 6}
  ] &;

Manipulate[
 Floor[dim],
 {{dim, 1, "Day in month"}, 1, 31, MyGauge}
]

This code successfully produces the following gauge:

The problem I am having relates to the label. Note that the value shown includes a fractional part, when I would really like to display just the integer part.

I have tried various workarounds:

• Use of GaugeLabels->Automatic (* Same value as above *)
• Explicit use of Floor[#1] (* Results in display of ⌊value⌋ *)
• Adding an explicit integer increment as a fourth arguments to the Manipulate control description (* Error *)

Note that the normal behavior of HorizontalGauges has the behavior I desire as the default:

HorizontalGauge[98.6, {0, 150}, GaugeLabels -> Automatic]

My question is: How can I produce a HorizontalGauge label that displays an integer version of its first argument? More generally, is it possible to display arbitrary functional transformations on the input arguments in the GaugeLabels?

Answer 1

Edit to add details of Echo to find out why this is the case

I think the issue here is getting the Round/Floor/other function in the right level of the expression. I played around with Map in a few positions of the label, and this seems to do what you want:

myGauge := 
  HorizontalGauge[#1, #2, 
    GaugeFrameStyle -> Gray, 
    GaugeFaceStyle -> LightOrange,
    GaugeLabels -> Placed[Floor /@ #1, Above], 
    ScaleDivisions -> {8, 6}] &;

Manipulate[Floor[dim], {{dim, 1, "Day in month"}, 1, 31, myGauge}]

To see the reason for this, you can use Echo (if you are using version 10.3 or above). Echo lets you have an extra formatted output cell that doesn't affect the evaluation of your original code. So to see what's happening, I changed the gauge function to this:

myGauge := HorizontalGauge[#1, #2, 
  GaugeFrameStyle -> Gray, 
  GaugeFaceStyle -> LightOrange, 
  GaugeLabels -> Echo[
    Placed[Floor /@ #1, Above], 
    "Gauge label: ", 
    FullForm
  ], 
  ScaleDivisions -> {8, 6}
] &;

When used in the manipulate you will then get an extra cell output of Gauge label: Placed[Dynamic[Floor[dim$$]],Above]

If we remove the /@ from it (so not mapping, just using Floor), the output is Gauge label: Placed[Floor[Dynamic[dim$$]],Above].

Floor is not designed to work on Dynamic objects (it only evaluates numerically on integers, reals etc) so that is why you do not get the expected output in the original code.

Answer 2

I can't see any easy way to directly do what you ask for with a Manipulate expression, but it becomes very easy when the function, DynmacicModule, that lurks behind Manipulate is used. This allows us to use the 2nd argument of Dynamic to constrain the values to integers.

DynamicModule[{val = 1},
  HorizontalGauge[Dynamic[val, (val = Round[#]) &], {1, 31},
    GaugeFrameStyle -> Gray,
    GaugeFaceStyle -> LightOrange,
    GaugeLabels -> Placed[Dynamic[Style[val, 20]], Above],
    ScaleDivisions -> {8, 6},
    ImageSize -> Large]]

Note that with this approach, not only is the label shown as a integer, but the gauge marker now moves in unit steps.

This approach can, of course, be used with a Manipulate expression inside it.

DynamicModule[{val = 1},
  Manipulate[
    Style[val, 20],
    Row[
      {Style["Day of the Month ", 14],
       HorizontalGauge[Dynamic[val, (val = Round[#]) &], {1, 31},
         GaugeFrameStyle -> Gray,
         GaugeFaceStyle -> LightOrange,
         GaugeLabels -> Placed[Dynamic[Style[val, 16]], Above],
         ScaleDivisions -> {8, 6},
         ImageSize -> 400]}]]]

Update

Spencer Rugaber has found a way to use my approach directly in a Manipulate expression; he simply initializes val with the Initialization option. See his comment below.