Cell evaluation and parallel kernels

Question

Is it possible to simply force Mathematica to evaluate one cell with let's say kernel A and another cell with kernel B etc. so that they can be evaluated in parallel? There is a similar answer here but I prefer avoiding creating cells manually. I would like it either in GUI or in some other simple way. The code is a plot creation. I would prefer each in separate cell. Is this even possible? Why cannot I simply right click a cell and assign a kernel :-(.

Answer 1

Basic approach

At first we configure parallel kernels either via the Evaluation ► Kernel Configuration Options menu item or programmatically via the EvaluatorNames global FrontEnd option. The following code defines 9 additional kernels which you'll able to assign to Cells in a Notebook (warning: if you already changed the Kernel Configuration Options, the following code will override these changes):

krnConfig = 
 Prepend[
  Table["krn" <> ToString[i] -> {"AppendNameToCellLabel" -> True,
                                 "AutoStartOnLaunch" -> False}, {i, 9}], 
        "Local" -> {"AutoStartOnLaunch" -> True}]

SetOptions[$FrontEnd, EvaluatorNames -> krnConfig]

{"Local" -> {"AutoStartOnLaunch" -> True}, 
 "krn1" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn2" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn3" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn4" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn5" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn6" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn7" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn8" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}, 
 "krn9" -> {"AppendNameToCellLabel" -> True, "AutoStartOnLaunch" -> False}}

Then we make a Palette with buttons corresponding to assigning of each of the configured kernels to notebook selection:

CreatePalette[
 Column@Prepend[
   Table[With[{name = "krn" <> ToString[i]}, 
     Button[name, (SetOptions[NotebookSelection[InputNotebook[]], 
         Evaluator -> name];)]], {i, 9}], 
   Button[Clear, (SetOptions[NotebookSelection[InputNotebook[]], 
       Evaluator -> Inherited];)]]]

Now you can simply select a Cell (or even several Cells or a cell group) and then press a button in order to assign the corresponding kernel to that Cell. If you wish to revert to the default kernel, press the Clear button.

Finally you can install this palette permanently by using the Palettes ► Install Palette... menu item.

---

Further elaboration

The above solution can be elaborated further. For example, if we wish to restrict our Palette to affect only "Input" Cells, we can modify it as follows (Mathematica version 9 or higher is required):

CreatePalette[
 Column@Prepend[
   Table[With[{name = "krn" <> ToString[i]}, 
     Button[name, (SetOptions[#, Evaluator -> name] & /@ 
         Cells[NotebookSelection[InputNotebook[]], CellStyle -> "Input"];)]], {i, 9}], 
   Button[Clear, (SetOptions[#, Evaluator -> Inherited] & /@ 
       Cells[NotebookSelection[InputNotebook[]], CellStyle -> "Input"];)]]]

If we wish to assign different individual kernels to selected "Input" Cells automatically, the following Palette will do this (the maximum number of individual kernels is assumed to be 9):

CreatePalette[
 Column[{Button["Assign individual kernels to selected Input Cells", 
    Function[cells, 
      If[TrueQ[1 <= Length[cells] <= 9], 
       MapIndexed[SetOptions[#, Evaluator -> "krn" <> ToString[#2[[1]]]] &, cells], 
       DialogInput[
        DialogNotebook[{TextCell["From 1 to 9 Input Cells must be selected"], 
          Button["OK", DialogReturn[]]}]]]][
     Cells[NotebookSelection[InputNotebook[]], CellStyle -> "Input"]]], 
   Button["Revert selected Input Cells to default kernel", 
    SetOptions[#, Evaluator -> Inherited] & /@ 
     Cells[NotebookSelection[InputNotebook[]], CellStyle -> "Input"]]}]]