How to get the $0$ result for this limit?

Question

Consider the following series:
$$\sigma (\text{x$\_$})\text{:=}\sqrt{\sum _{k=0}^{x-1} \frac{(x! x!) (-1)^{x-k}}{(x-k) (k! (2 x-k)!)}+\frac{\pi ^2}{12}}$$
From the following codes, it seems that the series tends to $0$ with a very low slope as $n$ approaches $+\infty$, this is the case in the article that I'm studying

σ[x_]:=Sqrt[Pi^2/12+Sum[(x!*x!)/(k!*(2 x-k)!)*(-1)^(x-k)/(x-k),{k,0,x-1}]]
Y=Table[σ[n],{n,0,1000}]//N;
ListLinePlot[Y,PlotRange->{0,1}]

but when I compute this limit, there are the results:

Limit[σ[n],n->Infinity]
(*Limit[Sqrt[π^2/12+(-1)^(2+2 n) (HarmonicNumber[n]-HarmonicNumber[2 n])],n->∞]*)

Limit[σ[n],n->Infinity]//N
(*Sqrt[0.822467 -0.693147 2.71828^((0. +2. I) Interval[{-6.67522*10^-308,3.14159}])]*)

Limit[σ[n],n->Infinity]//N//FullSimplify
(*Sqrt[(0. -0.693147 I) Interval[{-1,1}]+Interval[{0.12932,1.51561}]]*)  

How can I obtain $0$ as the result of this limit?

Answer 1

Observing strictly that the domain of x as the upper limit of the summation index is the integers, the limit exists, it can be calculated easily with Mathematica and it is different from zero.

We need to consider this sum

σWH[x_] := 
 Sqrt[π^2/12 + 
   Simplify[Sum[(x!*x!)/(k!*(2 x - k)!)*(-1)^(x - k)/(x - k), {k, 0, x - 1}], 
    x ∈ Integers]]

which is evaluated to

$$\text{$\sigma $WH}(\text{x}) = \sqrt{H_{\text{x}}-H_{2 \text{x}}+\frac{\pi ^2}{12}}$$

where $H_{\text{x}}$ is the harmonic number of x.

The limit is then

Limit[σWH[x], x -> ∞]

(* Out[232]= 1/2 Sqrt[π^2/3 - 4 Log[2]] *)

% // N

(* Out[233]= 0.359611 *)

This value is in good agreement with the asymptotic behaviour of your graph.

Addendum

The essence of the agument can be studied in this simpler example

Sum[(-1)^(x - k)/(x - k), {k, 0, x - 1}]

(* Out[303]= (-1)^(2 x) ((-1)^x LerchPhi[-1, 1, 1 + x] - Log[2]) *)

Simplify[%, x ∈ Integers]

(* Out[304]= (-1)^x LerchPhi[-1, 1, 1 + x] - Log[2] *)

Limit[%, x -> ∞]

(* Out[305]= -Log[2] *)

Answer 2

I think you will have to ask a mathematician if the limit is really 0 (or even real) since in Mathematica you can get this

s[x_] := Sqrt[
  Pi^2/12 + 
   Sum[(x!*x!)/(k!*(2 x - k)!)*(-1)^(x - k)/(x - k), {k, 0, x - 1}]]
s[x] // FullSimplify
Limit[s[x], x -> Infinity] // FullSimplify

So the limit seems to be complex, but I am not sure, I am not a mathematician. If you assume that you do the limit for integers, then you get this from Mathematica

Assuming[Element[x, Integers],Limit[s[x], x -> Infinity]] // FullSimplify
N[%]
(*1/2 Sqrt[π^2/3 - 4 Log[2]]*)
(*0.359611*)

which is not 0.