What is the equivalent of MATLAB's accumarray?

Question

Is there any equivalent of MATLAB's accumarray?

I'm looking for an equivalent of:

accumarray(A(:),B(:),[],@mean)

where A and B are two matrix datasets.

EDIT: As asked in the comment, I will provide a bit more from the MATLAB code. As far as I understood, the first matrix contains a set of radius values (all integer values), the second contains a random pattern (here 0's and 1's) like this:

(* A(:) *)
a = Table[Round@Sqrt[x^2 + y^2], {y, -5, 5, 1.}, {x, -5, 5, 1}];
(* B(:) *)
SeedRandom[1238];
b = Table[x y, {y, RandomInteger[1, 5]}, {x, RandomInteger[1, 5]}] 

Now accumarray(A(:),B(:),[],@mean) seems to virtually collect all matrix elements of $b$ where the elements $a_{ij}$ share the same value and than the function @mean is applied to all those virtually collected values. After this the obtained values are written in a List containing {Value of a, mean of all values of b}. I think this is what the code is supposed to do.

Answer 1

 SeedRandom[1238];
 n = 10;
 m = 100;
 f = Mean;
 a = RandomInteger[{1, n}, {m, 2}];
 b = RandomInteger[{0, 1}, {m}];

The first application of accumarray that came to my mind is the assembly of SparseArrays. This can be directly done with

sparseresult = With[{spopt = SystemOptions["SparseArrayOptions"]},
  Internal`WithLocalSettings[
   SetSystemOptions["SparseArrayOptions" -> {"TreatRepeatedEntries" -> f@*List}],
   SparseArray[a -> b],
   SetSystemOptions[spopt]]
  ];
sparseresult["NonzeroValues"]

A more flexible (but not as efficient way) to do it is by using GrouBy as follows

groupbyresult = Map[
  f,
  GroupBy[Transpose[{a, b}], First -> Last]
  ]

An alternative way can be obtained with Merge

mergeresult = Merge[
  Association /@ Thread[Rule[a, b]],
  f
  ]

Note that the ordering of the resulting array is not uniquely defined. Hence, using Associations is a robust way to represent it.