Why does the image of this parameterization appear disconnected?

Question

Why the image of this parameterization appears disconnected. Thanks.

  X=6Cos[u](1+Sin[u])+4(1-Cos[u]/2)Cos[u]Cos[v];
  Y=16Sin[u]+4(1-Cos[u]/2)Sin[u]Cos[v];
  Z=4(1-Cos[u]/2)Sin[v];
  p1=ParametricPlot3D[Evaluate[{X,Y,Z}],{u,0,Pi},{v,0,2Pi},Axes->False,Boxed->False]

X=6Cos[u](1+Sin[u])+4(1-Cos[u]/2)Cos[v+Pi];
Y=16Sin[u];
Z=4(1-Cos[u]/2)Sin[v];
p2=ParametricPlot3D[Evaluate[{X,Y,Z}],{u,Pi,2Pi},{v,0,2Pi},Axes->False,Boxed->False]

Row[{p1,p2}]

bx=6Cos[u](1+Sin[u]); by = 16 Sin[u]; r=4(1-Cos[u]/2); 
X=If[Pi<u<=2Pi,bx+r Cos[v+Pi],bx+r Cos[u]Cos[v]];
Y=If[Pi<u<=2Pi, by, by+r Sin[u]Cos[v]];
Z=r Sin[v];
p= ParametricPlot3D[Evaluate[{X,Y,Z}],{u,0,2Pi},{v,0,2Pi},PlotPoints->32,Axes->False,Boxed->False,ViewPoint->{1.4,-2.6,-1.7}]

Show[p,ViewPoint->{1,0,1}]

Answer 1

$Version

(* "13.2.1 for Mac OS X ARM (64-bit) (January 27, 2023)" *)

Clear["Global`*"]

With my system, your code produces the gap.

bx = 6 Cos[u] (1 + Sin[u]); by = 16 Sin[u]; r = 4 (1 - Cos[u]/2);
X = If[Pi < u <= 2 Pi, bx + r Cos[v + Pi], bx + r Cos[u] Cos[v]];
Y = If[Pi < u <= 2 Pi, by, by + r Sin[u] Cos[v]];
Z = r Sin[v];
p = ParametricPlot3D[Evaluate[{X, Y, Z}], {u, 0, 2 Pi}, {v, 0, 2 Pi}, 
  PlotPoints -> 32, Axes -> False, Boxed -> False, ViewPoint -> {1, 0, 1}]

The issue arises from the Automatic setting for Exclusions

Options[ParametricPlot3D, Exclusions]

(* {Exclusions -> Automatic} *)

To eliminate the gap, preclude any Exclusions

p4 = ParametricPlot3D[Evaluate[{X, Y, Z}], {u, 0, 2 Pi}, {v, 0, 2 Pi}, 
  PlotPoints -> 32, Axes -> False, Boxed -> False, ViewPoint -> {1, 0, 1}, 
  Exclusions -> None]