Creating rule-based sublists

Question

I have a list each element of which consists of a list containing two strings and two integers:

lis = {{"ab", 2, "c", 3}, {"d", 3, "e", 4}, {"ac", 5, "f", 6}, {"c", 7, "d", 8}, {"ad", 9, "c", 10}}

I would like to create a new list that includes every member of lis whose first element starts with "a":

res = {{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

This would seem to be a simple task for StringCases, but I am not having much luck; suggestions would be gratefully received.

Answer 1

Pick[lis, StringTake[lis[[All, 1]], 1], "a"]

Pick[lis, StringPart[lis[[All, 1]], 1], "a"]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Less elegantly readable ones that use ToCharacterCode:

Pick[lis, 
 First@ToCharacterCode@First@# == Sequence @@ ToCharacterCode["a"] & /@
   lis]

Pick[lis, 
 lis[[All, 1]] /. s_String -> ToCharacterCode[s] // Map[First], 
 Sequence @@ ToCharacterCode["a"]]

Answer 2

Some options:

Pick[
 lis,
 StringStartsQ[lis[[All, 1]], "a"]
 ]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Select[lis, StringStartsQ[First[#], "a"] &]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Cases[lis, {_?(StringStartsQ["a"]), ___}]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Answer 3

Alternate solutions using string patterns:

Pick[lis, StringMatchQ[lis[[All, 1]], "a" ~~ ___]]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Pick[lis, StringCases[lis[[All, 1]], "a" ~~ ___] // Map[Length], 1]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Pick[lis, StringPosition[lis[[All, 1]], "a" ~~ ___] // Map[MatrixQ]]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Answer 4

A few additional variations:

Pick[lis, StringMatchQ["a*"]@lis[[All, 1]]]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Pick[lis, StringTake[lis[[All, 1]], 1], "a"]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Pick[lis, Order[#, "b"]& /@ lis[[All, 1]], 1]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Answer 5

Another way using ReplaceAll:

lis /. x : {___} /; StringQ[x[[1]]] :> If[StringStartsQ[x[[1]], "a"], x, Nothing]

(*{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}*)

Answer 6

ReplaceAt[lis, _?(Not @* StringStartsQ["a"]) :> Nothing, {All, 1}]

{{"ab", 2, "c", 3}, {3, "e", 4}, {"ac", 5, "f", 6}, {7, "d", 8}, {"ad", 9, "c", 10}}

Answer 7

list = 
  {{"ab", 2, "c", 3}, {"d", 3, "e", 4}, {"ac", 5, "f", 6}, 
   {"c", 7, "d", 8}, {"ad", 9, "c", 10}};

Using Extract

p = Position[list, {a_String /; StringStartsQ[a, "a"], __}]

Extract[p] @ list

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Using SequenceSplit (new in 11.3)

Catenate @ SequenceSplit[list, {{x_ /; Not @ StringStartsQ[x, "a"], __}}]

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}

Answer 8

Using Association and Merge

lis = {{"ab", 2, "c", 3}, {"d", 3, "e", 4}, {"ac", 5, "f", 6}, {"c", 7,
     "d", 8}, {"ad", 9, "c", 10}};
"a" /. Merge[Association[StringTake[#[[1]], 1] -> #] & /@ lis, 
  Identity]

gives:

{{"ab", 2, "c", 3}, {"ac", 5, "f", 6}, {"ad", 9, "c", 10}}