Not 100% clear from the question but I tried to reproduce the integral

Integrate[Sqrt[1 + b + 2 a x], {x, x1, x2}]

(* ConditionalExpression[(-(1 + b + 2 a x1)^(
   3/2) + (1 + b + 2 a x2)^(3/2))/(3 a), 
 Re[(1 + b + 2 a x1)/(2 a x1 - 2 a x2)] > 1 || 
  Re[(1 + b + 2 a x1)/(2 a x1 - 2 a x2)] < 0 || (1 + b + 2 a x1)/(
   2 a x1 - 2 a x2) ∉ Reals] *)

I got a different answer (so again, not sure if I reproduced the integral as intended).

To get rid of the Conditional I made some assumptions that it was desired to stay in the Real domain.

Assuming[
 Element[a && b && x1 && x2, Reals] && b + 2 a x1 > 1 && 
  b + 2 a x2 > 1, Integrate[Sqrt[1 + b + 2 a x], {x, x1, x2}]]

(* (1/(3 a))(-Sqrt[1 + b + 2 a x1] - 
  2 a x1 Sqrt[1 + b + 2 a x1] + Sqrt[1 + b + 2 a x2] + 
  2 a x2 Sqrt[1 + b + 2 a x2] + 
  b (-Sqrt[1 + b + 2 a x1] + Sqrt[1 + b + 2 a x2])) *)

Then using the output above Solve produced a result (note: I used lower-case "l" rather than upper-case "L", a general recommendation is to stay away from upper-case symbols so as not to collide with pre-defined system symbols).

Solve[
 l == 1/(3 a) (-Sqrt[1 + b + 2 a x1] - 2 a x1 Sqrt[1 + b + 2 a x1] + 
     Sqrt[1 + b + 2 a x2] + 2 a x2 Sqrt[1 + b + 2 a x2] + 
     b (-Sqrt[1 + b + 2 a x1] + Sqrt[1 + b + 2 a x2])), x2]

(* {{x2 -> -((1 + b)/(2 a)) + 
    1/2 (1/a^3 + (3 b)/a^3 + (3 b^2)/a^3 + b^3/a^3 + (9 l^2)/a + (
       6 x1)/a^2 + (12 b x1)/a^2 + (6 b^2 x1)/a^2 + (12 x1^2)/a + (
       12 b x1^2)/a + 8 x1^3 + (6 l Sqrt[1 + b + 2 a x1])/a^2 + (
       6 b l Sqrt[1 + b + 2 a x1])/a^2 + (
       12 l x1 Sqrt[1 + b + 2 a x1])/a)^(1/3)}, {x2 -> -((1 + b)/(
     2 a)) - 1/
     4 (1 - I Sqrt[3]) (1/a^3 + (3 b)/a^3 + (3 b^2)/a^3 + b^3/a^3 + (
       9 l^2)/a + (6 x1)/a^2 + (12 b x1)/a^2 + (6 b^2 x1)/a^2 + (
       12 x1^2)/a + (12 b x1^2)/a + 8 x1^3 + (
       6 l Sqrt[1 + b + 2 a x1])/a^2 + (6 b l Sqrt[1 + b + 2 a x1])/
       a^2 + (12 l x1 Sqrt[1 + b + 2 a x1])/a)^(1/3)}, {x2 -> -((
     1 + b)/(2 a)) - 
    1/4 (1 + I Sqrt[3]) (1/a^3 + (3 b)/a^3 + (3 b^2)/a^3 + b^3/a^3 + (
       9 l^2)/a + (6 x1)/a^2 + (12 b x1)/a^2 + (6 b^2 x1)/a^2 + (
       12 x1^2)/a + (12 b x1^2)/a + 8 x1^3 + (
       6 l Sqrt[1 + b + 2 a x1])/a^2 + (6 b l Sqrt[1 + b + 2 a x1])/
       a^2 + (12 l x1 Sqrt[1 + b + 2 a x1])/a)^(1/3)}} *)

Update

With the corrected integration equations

Assuming[Element[a | b | x1 | x2, Reals],
 Integrate[Sqrt[1 + (2 a x + b)^2], {x, x1, x2}]
]

(* ConditionalExpression[(1/( 
 4 a))(-b Sqrt[1 + (b + 2 a x1)^2] - 2 a x1 Sqrt[1 + (b + 2 a x1)^2] +
    b Sqrt[1 + (b + 2 a x2)^2] + 2 a x2 Sqrt[1 + (b + 2 a x2)^2] - 
   ArcSinh[b + 2 a x1] + ArcSinh[b + 2 a x2]), x1 < x2] *)

Define a function to create the forward model for l given the other inputs:

lfun[a_, b_, x1_, x2_] := 
 1/(4 a) (-b Sqrt[1 + (b + 2 a x1)^2] - 
    2 a x1 Sqrt[1 + (b + 2 a x1)^2] + b Sqrt[1 + (b + 2 a x2)^2] + 
    2 a x2 Sqrt[1 + (b + 2 a x2)^2] - ArcSinh[b + 2 a x1] + 
    ArcSinh[b + 2 a x2])

Compute a test example

lfun[1, 2, 1, 2] // N

(* 5.1003 *)

Use FindMinimum to compute x2 assuming the other inputs are known:

With[
 {
  a = 1,
  b = 2,
  x1 = 1,
  l = 5.1003
  },
 FindMinimum[(l - lfun[a, b, x1, x2])^2, x2]
 ]

(* {1.76173*10^-20, {x2 -> 2.}} *)