AxesLabel broken in Version 10 for 3D plots?

Question

In version 10.0.1 (Win7), AxesLabel with arbitrary text strings works as expected in 2D plots:

Plot[Sin[x], {x, -4, 4}, 
 AxesLabel -> {"Range (km)", "Velocity (m/sec)"}]

In prior versions the same worked for 3D plots as well; but not anymore in v. 10:

Plot3D[Sin[x - 3 y], {x, -3, 3}, {y, -3, 3}, 
 AxesLabel -> {"Range (km)", "Velocity (m/sec)"}, 
 LabelStyle -> Directive[Blue, Large]]

Is this a bug? And is there a workaround?

Thanks

Answer 1

Let me expand my comment. As I wrote, you can write

AxesLabel -> {"Range (km)", "Velocity (m/sec)", ""}

One label also works fine

AxesLabel -> {"Range (km)"}

But two labels doesn't work

AxesLabel -> {"Range (km)", "Velocity (m/sec)"}

Unfortunately it is equivalent to AxesLabel -> Automatic. The problem is in the definition of Visualization`Utilities`AxesLabelQ

Visualization`Utilities`AxesLabelQ[#, 3] & /@ {{"x"}, {"x", "y"}, {"x", "y", "z"}}

{True, False, True}

You can repair it by the following command

Unprotect[Visualization`Utilities`AxesLabelQ];
Visualization`Utilities`AxesLabelQ[{_?
     Visualization`Utilities`OptionsDump`axislabelTokenQ, _?
     Visualization`Utilities`OptionsDump`axislabelTokenQ}, 
   Visualization`Utilities`OptionsDump`n_: 3] /; 
  Visualization`Utilities`OptionsDump`n === 3 := True
Protect[Visualization`Utilities`AxesLabelQ];

Now everything works as desired

Plot3D[Sin[x - 3 y], {x, -3, 3}, {y, -3, 3}, 
 AxesLabel -> {"Range (km)", "Velocity (m/sec)"}]

Answer 2

There are bugs within bugs. Consider this sequence:

V9

$Version

"9.0 for Microsoft Windows (64-bit) (January 25, 2013)"

Plot3D[Sin[x - 3 y], {x, -3, 3}, {y, -3, 3},
 ImageSize -> 500,
 AxesLabel -> {"Range (km)", "Velocity (m/sec)"},
 LabelStyle -> Directive[Blue, Large]]

Plot3D[Sin[x - 3 y], {x, -3, 3}, {y, -3, 3},
 ImageSize -> 500,
 AxesLabel -> {"Range (km)", "Velocity (m/sec)", Automatic},
 LabelStyle -> Directive[Blue, Large]]

V10

$Version

"10.0 for Microsoft Windows (64-bit) (June 29, 2014)"

Plot3D[Sin[x - 3 y], {x, -3, 3}, {y, -3, 3},
 AxesLabel -> {"Range (km)", "Velocity (m/sec)"},
 LabelStyle -> Directive[Blue, Large],
 PlotTheme -> "Classic",
 ImageSize -> 500]

Plot3D[Sin[x - 3 y], {x, -3, 3}, {y, -3, 3},
 AxesLabel -> {"Range (km)", "Velocity (m/sec)", Automatic},
 LabelStyle -> Directive[Blue, Large],
 PlotTheme -> "Classic",
 ImageSize -> 500]

Well, I accept and welcome that V10 requires the third Automatic - parameter. I am, however, hesitant to accept that blue turns to black and that classic isn't classic anymore.