How is + as an infix operator associated with Plus?

Question

How is + associated with Plus? Suppose I want to define a head FooBar and have it associated with a unicode character of my choice, ideally used as an infix form, i.e.

FooBar[x, y]

is equivalent

x ↗ y

as seen by the kernel. How this kind of thing can be done?

Answer 1

I can't answer how the association is made for the built-in operators, but I can show how to add your own. If your symbol is already an operator you can do this simply as halirutan showed.

This question may be a duplicate of How can one define an infix operator with an arbitrary unicode character? but since it admits a simpler interpretation I shall not close it as such. Drawing from both Jens' and my own answer we can do the following. It requires editing a low level system file, so make careful back-ups. The format is described in the linked Q&A.

Here I will define an entirely new operator I shall call PennyOp, with a Unicode character mapping and an input alias.

Find your UnicodeCharacters.tr file in SystemFiles\FrontEnd\TextResources\ or using the path given by:

System`Dump`unicodeCharactersTR

(at least in version 10.1 one can also copy this file to the matching path in $UserBaseDirectory)

and add this line:

0x20B0      \[PennyOp]      ($penny$)    Infix       155     None        5       5

You can then use EscpennyEsc to enter the operator, which is recognized as such:

Adding Jens' MakeExpression definition:

MakeExpression[RowBox[{x_, "\[PennyOp]", y_}], StandardForm] :=
  MakeExpression[RowBox[{"PennyOp", "[", x, ",", y, "]"}], StandardForm]

Now:

You can define PennyOp as you would any other Symbol:

PennyOp[n_Integer, s_String] := "" <> Riffle[Table[s, {n}], " "]

5 \[PennyOp] "word"

"word word word word word"

Presto, custom Unicode-character operator with custom precedence and binding. It will only work in the Front End however.

Answer 2

Maybe I miss the point here, but

FullForm[x ↗ y]

gives UpperRightArrow[x,y]. This is described in the documentation to UpperRightArrow and since this symbol is not protected and has not built-in meaning, you can just define it the way you like:

UpperRightArrow[x_, y_] := FooBar[x, y]

and this instantly gives you

Update: As answer to Jacobs comment I want to point out, that I defined the FooBar definition so verbosely to show, that it works like a normal function definition. Of course, the most easy method is just to say

UpperRightArrow = FooBar

About your first question, I can only make an educated guess, because I don't know the implementation. The association of the infix + and the Plus happens during parsing, because what you see when you use something like FullForm[Expand[(a + b)^3]] is the parse tree after the expression was evaluated.

In the official docs, I found only in the tutorial Operators without Built-in Meanings a hint to your question:

When you enter a piece of input such as 2+2, Mathematica first recognizes the + as an operator and constructs the expression Plus[2, 2], then uses the built-in rules for Plus to evaluate the expression and get the result .

Answer 3

The Notation package is the most convenient way to define new notation(s).

<<Notation`

Define an infix notation. You can use the palette that the 'Notation` package pops up to do this.

InfixNotation[ParsedBoxWrapper["\[UpperRightArrow]"], FooBar]

Check that the infix notation maps to the correct FullForm expression.

x \[UpperRightArrow] y // FullForm