How do you selectively flatten a sublist in a given list?

Question

I have a list that looks something like:

d={{{1}},{{2}},{{3},{4}},{{5}},{{1},{8}}}

Is there a generic way to use flatten so that you can selectively target elements within a specific sublist or is another function necessary? The output I'm looking to get is:

finald={{{1}},{{2}},{{3,4}},{{5}},{{1,8}}}

Answer 1

SubsetMap[Map[Transpose], d, {3, 5}]

 {{{1}}, {{2}}, {{3, 4}}, {{5}}, {{1, 8}}}  

Also

SubsetMap[Map[List@*Flatten], d, {3, 5}]

SubsetMap[Map[List@*Apply[Join]], d, {3, 5}]

MapAt[Transpose, d, {{3}, {5}}]

Answer 2

MapAt[{Flatten[#]} &, d, {{3}, {5}}]

(* if you don't know the position, but know the elements *)
MapAt[{Flatten[#]}&, d, 
  Join[
    Position[d, {{3}, {4}}],
    Position[d, {{1}, {8}}]
  ]
]

Answer 3

Since you want to flatten by pattern rather than position:

d = {{{1}}, {{2}}, {{3}, {4}}, {{5}}, {{1}, {8}}};

toFlat = {{3}, {4}} | {{1}, {8}};

d /. x : toFlat :> Flatten[x]

{{{1}}, {{2}}, {3, 4}, {{5}}, {1, 8}}

Also works with general patterns:

toFlat = {{3 | 1}, _};

d /. x : toFlat :> Flatten[x]

{{{1}}, {{2}}, {3, 4}, {{5}}, {1, 8}}