5
$\begingroup$

The Archimedes spiral equation in parametric form:

fx[t_] := Cos[t]*t;
fy[t_] := Sin[t]*t;

How can it be converted to implicit form?

Is there a general method to convert any parametric equation to implicit form?

$\endgroup$
4
  • 1
    $\begingroup$ The spiral of Archimedes can indeed be expressed as an implicit Cartesian equation, but it isn't pretty or more useful than the parametric or polar one: x Tan[Sqrt[x^2 + y^2]] == y $\endgroup$ Nov 15, 2019 at 16:39
  • $\begingroup$ @J.M.willbebacksoon I included the spiral of Archimedes for possible input. The solutions to this issue that I found here could not cope with this curve. $\endgroup$
    – PavelDev
    Nov 15, 2019 at 16:50
  • $\begingroup$ In principle, if the components of the parametric equations only have trigonometric functions of the parameter, one can derive an implicit Cartesian equation (e.g. this). Otherwise, there isn't any general method that would work on e.g. {x == Exp[t] + t^2, y == t - Cos[t]}. $\endgroup$ Nov 15, 2019 at 16:56
  • $\begingroup$ @J.M.willbebacksoon "Otherwise, there isn't any general method that would work" How is it prove in mathematics? $\endgroup$
    – PavelDev
    Nov 15, 2019 at 17:13

1 Answer 1

8
$\begingroup$
fx[t_] := Cos[t]*t;
fy[t_] := Sin[t]*t;

ParametricPlot[{fx[t], fy[t]}, {t, 0, 10}]

enter image description here

sol = Assuming[Element[{x, y}, Reals],
  Eliminate[{x == fx[t], y == fy[t]}, t,
    InverseFunctions -> True] //
   FullSimplify]

t^2 == x^2 + y^2 && x == t Cos[t]

Since t was not eliminated

solxy = sol[[-1]] /. Solve[sol[[1]], t, Reals] // FullSimplify

(* {x + Sqrt[x^2 + y^2] Cos[Sqrt[x^2 + y^2]] == 0, 
 x == Sqrt[x^2 + y^2] Cos[Sqrt[x^2 + y^2]]} *)

The result is the original spiral and its mirror

ContourPlot[Evaluate@solxy,
 {x, -10, 10}, {y, -10, 10},
 AspectRatio -> 1,
 PlotPoints -> 100,
 MaxRecursion -> 5]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.