unexpected result from augmented assignment to association

Question

Is the last of these results expected? If so, how?

assoc=<|"a"->1,"b"->2|>;
assoc["a"]+=1;
assoc (* <|"a" -> 2, "b" -> 2|> *)
assoc[[{"a","b"}]]=1;
assoc  (* <|"a" -> 1, "b" -> 1|> *)
assoc[[{"a","b"}]]+=1;
assoc  (* <|"a" -> <|"a" -> 2, "b" -> 2|>, "b" -> <|"a" -> 2, "b" -> 2|>|> *)

Edit:

Kuba helpfully points out that this reflects the behavior of Part, specifically

assoc = <|"a" -> 1, "b" -> 2|>;
assoc[[{"a", "b"}]]  (* <|"a" -> 1, "b" -> 2|> *)

Unfortunately, this pushes my question back to the behavior of Part. We are told by the docs that Part[expr,i] gives the ith part of expr and that Part[expr,{i1,i2,…}] gives a list of the parts i1, i2, … of expr. This seems to imply that

Part[expr, {i1,i2,...}]==(Part[expr,#]&/@{i1,i2,...})

But this is clearly not the case for associations. E.g.,

assoc[[#]] & /@ {"a", "b"}     (* {1,2} *)

How am I misreading the docs?

Answer 1

Maybe not at the first sight but it is expected once you think more about this.

 assoc[[{"a", "b"}]] +=1

is

assoc[[{"a", "b"}]] = (assoc[[{"a", "b"}]] + 1 )

and while rhs operation is still ok, the following one is not defined for associations (not counting generic assignment to values):

assoc[[{"a", "b"}]] = <|"a" -> 2, "b" ->3|>

in case of Lists only dimensions play a role for threading but here keys too. There are Merge and friends for this kind of operations and by default it will just treat it as a single element rhs case, assigning association to each value.

Trace also makes sense:

assoc[[{"a", "b"}]] += 1; // Trace

{ assoc[[{a,b}]]+=1;
, { assoc[[{a,b}]]+=1
, { { assoc
    , <|a->1,b->2|>
    }
  , <|a->1,b->2|>[[{a,b}]]
  , <|a->1,b->2|>
  }
, { assoc[[{a,b}]]=<|a->2,b->3|>
  , <|a->2,b->3|>
  }
, <|a->2,b->3|>
}
, Null
}