How to add a `Style` string or `Hyperlink` in CloudDeploy?

Question

There are two wrong code like this:

The first problem is I want to put the red string to Title.

CloudDeploy[
 FormFunction[{"x" -> "Integer"}, #x! &, 
  AppearanceRules -> <|
    "Title" -> StringTemplate["This is a ``.", 
       InsertionFunction -> (ToString[#, TraditionalForm] &)
      ][ Style["RED", Red]]
  |>], 
"myform", Permissions -> "Public"]

The second problem is I want to put the Hyperlink to Description.

CloudDeploy[
 FormFunction[{"x" -> "Integer"}, #x! &, 
  AppearanceRules -> <|
    "Title" -> StringTemplate["This is a ``", 
       InsertionFunction -> (ToString[#, TraditionalForm] &)
    ][ Hyperlink["Sample Image","http://pan.baidu.com/s/1xCeUq"]]
  |>
], "myform", Permissions -> "Public"]

So is this a bug or are there some method to realize it?

Answer 1

The answer is, don't convert everything to string.

It seems that Cloud can't work with String representation of Boxes so let's use real expression instead:

CloudDeploy[
 FormFunction[
  {"x" -> "Integer"}, #x! &,
  AppearanceRules -> <|
    "Title" -> Row[{"This is a", Spacer@1, Style["RED", Red], "."}]
    |>
  ],
 "myform",
 Permissions -> "Public"]

Notice that I have put there Spacer[1] before RED, that's because Whitespaces are trimmed in the Row, I don't know why...

The same solution works for you second problem:

"Title" ->
 Row[{"This is a", Spacer@1, 
   Hyperlink["Sample Image", "http://pan.baidu.com/s/1xCeUq"], "."}]