Shading regions in ParametricPlot

Question

I am using ParametricPlot to get an X vs Y plot. I want to shade the area enclosed by the curve falling in the region where Y<0.

For example, how to shade the area enclosed by the Sin curve where Sin[x]<0.

ParametricPlot[{x, Sin[x]}, {x, 0, xm}]

Answer 1

 ParametricPlot[{ u, If[Sin[u] < 0, v, 1] Sin[u]},
   {u, -2 Pi, 2 Pi}, {v, 0, 1},
   AspectRatio -> 1, Mesh -> False,
   PlotStyle -> Directive[Red, Opacity[.8]]]

ParametricPlot[{ u, If[Sin[u] < 0, v, 1] Sin[u]},
 {u, -2 Pi, 2 Pi}, {v, 0, 1},
 Mesh -> False, AspectRatio -> 1, 
 ColorFunction -> Function[{x, y, u, v}, Hue[v]], 
 PlotPoints -> 100]

Update: Few alternatives that use {u, v Sin[u]} as the first argument of ParametricPlot:

Using ColorFunction:

ParametricPlot[{ u, v Sin[u]}, {u, -2 Pi, 2 Pi}, {v, 0, 1},
AspectRatio -> 1, Mesh -> False,
ColorFunction -> (If[Sin[#1] > 0, White, Red] &),
ColorFunctionScaling -> False,
PlotPoints -> 100]

Using Mesh, MeshFunctions and MeshStyle:

ParametricPlot[{u, v Sin[u]}, {u, -2 Pi, 2 Pi}, {v, 0, 1}, 
   AspectRatio -> 1,
   Mesh -> {{0.}},
   MeshFunctions -> {Function[{x, y, u, v}, y]},
   MeshShading -> {Red, White},
   PlotPoints -> 100]

Answer 2

Evaluation is faster than Verde's solution plus this little deviation close to the intersection is gone: Make a second plot of y Min[Sin[x],0.0] with y as an additional variable, so you can use the mesh to fill the area.

ParametricPlot[{{x, Sin[x]}, {x,y Min[Sin[x],0.0]}},
                 {x, 0, 2 Pi }, {y, 0, 1}, PlotRange -> All, AspectRatio -> 1, Mesh -> False]

But it does not work perfectly, e.g. for a filling sin(x)<0.1.

Answer 3

You could do:

ParametricPlot[{{x, Sin[x]}, {x, y}}, {x, 0, 2 Pi}, {y, 0, Min[0, Sin@x]}, 
               Mesh -> None, PlotPoints -> 50, PlotRange -> {{0, 2 Pi}}]

Edit

Using Plot[] is much easier

Plot[Sin@x, {x, 0, 2 Pi}, Filling -> {1 -> {Axis, {Yellow, None}}}]