FindFit returns worse result when putting constraints on parameters

Question

I want to fit some data to a model of exponential decay using the FindFit function:

data = {{0, 78}, {24, 64.5}, {48, 70.5}, {96, 54}, {144, 64.5}, {216, 3}, {336, 0}, {696, 0}};
model = data[[1, 2]]*Exp[-k1*t];

fit1 = FindFit[data, model, k1, t]
fit2 = FindFit[data, {model, k1 > 0}, k1, t]

modelf1 = Function[{t}, Evaluate[model /. fit1]];
modelf2 = Function[{t}, Evaluate[model /. fit2]];

Plot[#[t], {t, 0, 696}, Epilog -> Map[Point, data], PlotRange -> All] & /@ {modelf1, modelf2}

Interestingly, the model with no specified constraint on k1 finds a much better solution than the constrained model, but the solution of the unconstrained problem falls within the range of the constrained one. Here is the output:

---

{k1 -> 0.00512571}
{k1 -> 1.01979}

Why isn't the solution to the constrained problem at least as good as the solution of the unconstrained one?

Answer 1

It is because your constraint forces the path chosen for finding a local extrema. You could verify it by doing:

data ={{0, 78}, {24, 64.5}, {48, 70.5}, {96, 54}, {144, 64.5}, {216, 3}, {336, 0}, {696, 0}};
model = data[[1, 2]]*Exp[-k1*t];
l = {}; l1 = {};
fit1 = FindFit[data,  model, k1,          t, EvaluationMonitor :> AppendTo[l, k1]]
fit2 = FindFit[data, {model, k1 > 0}, k1, t, EvaluationMonitor :> AppendTo[l1, k1]]

Show[ListLinePlot[{l1,l}], 
         ListPlot[{l1,l},PlotStyle ->{{Blue,PointSize[Large]}, {Red,PointSize[Medium]}}]]

Edit

As for why some methods fail, you can see your extrema is very sharp:

f[k1_] := Total[(data[[1, 2]]*Exp[-k1*#[[1]]] - #[[2]])^2 & /@ data];
Plot[{f[k1], Evaluate[D[f[k2], k2] /. k2 -> k1]}, {k1, -1, 1}, 
 PlotRange -> {{-.1, .4}, {0, 16500}}, Axes -> {True, False}, Frame -> True]

Answer 2

Different methods are used for constrained and unconstrained problems.
Compare for example

data = {{0, 78}, {24, 64.5}, {48, 70.5}, {96, 54}, {144, 64.5}, {216, 
    3}, {336, 0}, {696, 0}};
model = data[[1, 2]]*Exp[-k1*t];
methods = {Automatic, "ConjugateGradient", "Gradient", 
          "LevenbergMarquardt", "Newton", "QuasiNewton",
         {"NMinimize", Method -> "NelderMead"},
         {"NMinimize", Method -> "DifferentialEvolution"}, 
         {"NMinimize", Method -> "SimulatedAnnealing"},
         {"NMinimize", Method -> "RandomSearch"} };


fit1 = FindFit[data, model, k1, t, Method -> #] & /@ methods;
fit2 = (FindFit[data, {model, k1 > 0}, k1, t, Method -> #] & /@ methods) \
       /. FindFit[__] -> "NA";

TableForm[Transpose@{fit1, fit2}, TableAlignments -> Left, 
          TableHeadings -> {methods, {"Unconstrained", "Constrained"}}]

Note the warnings of the type Method -> XXX can only be used for unconstrained problems.

We see that NMinimize was the only method suitable for this constrained problem. For the unconstrained problem the "Gradient" method was probably used.

Oh, and if you want the table LeftAlignment to actually work, check out this great answer.