Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I have some elements in a Grid. I want to change their positions within that Grid. Can I swap their positions just by dragging cursor on to them?

For example

       Grid[{{1, 2, 5, 7, 9}, {3, 4, 8, 4, 2}, {5, 12, 7, 3, 8}}]

I want to swap positions of 8 and 2 in drag&drop fahion. Is it possible?

share|improve this question
1  
Would you mind adding in the code to get your (or an equivalent) Grid? That would make experiments easier. Your average standard Grid will not be interactive. –  Yves Klett Aug 22 '12 at 11:58
    
"not manually but moving cursors within that Grid". Moving cursors is not "manually"? –  belisarius Aug 22 '12 at 12:13
    
Do you want something akin to drag and drop interactivity? –  Yves Klett Aug 22 '12 at 12:22
    
@YvesKlett: Yes... –  Jennifer Aug 22 '12 at 12:23
    
Please see the edit (and modify after your taste). –  Yves Klett Aug 22 '12 at 12:28

1 Answer 1

up vote 11 down vote accepted

While drag'n'drop isn't officially supported in Mathematica currently (Depending on your definition of support), I believe Wolfram is working on it for a future version, or at least more direct support. I can't remember which screencast, but something was mentioned about this in one of Steven Wolframs talks posted on the official Mathematica blog.

Now to the code, what I do is simply spray around a lot of eventhandlers that set an Id when the mouse is over them, and then wrap my dynamic interface in an eventhandler that calls whatever action I need when you drag from one id to another.

SetAttributes[idElement,HoldFirst]
idElement[currentId_,content_,id_]:=EventHandler[content,{"MouseMoved":>(currentId=id)}]

In this case the action we want to perform is to switch the two elements that have been selected:

action[from_,to_] := If[from!=to,
   {mygrid[[Sequence@@from]],mygrid[[Sequence@@to]]}//
        ({mygrid[[Sequence@@to]],mygrid[[Sequence@@from]]}=#)&]

Now it's just a case of defining the outer EventHandler that calls the action, and a DynamicModule to scope the variables used, just to keep the code nice.

mygrid = {{1, 2, 5, 7, 9}, {3, 4, 8, 4, 2}, {5, 12, 7, 3, 8}};

DynamicModule[{currentId, from},
    EventHandler[Dynamic[

    Grid[MapIndexed[idElement[currentId, #1, #2] &, mygrid, {2}]]

    ],{
      "MouseDown" :> (from = currentId),
      "MouseUp" :> action[from, currentId]
     }]
]

This implementation is however not "just" allowing elements to be swapped, and depending on what you are doing, you may need a lot more interactivity added. For instance you can't edit the number anymore for this simple Grid example

Update:

A slightly nicer method which used unevaluated idTags which are only later replaced to allows a nicer call syntax:

SetAttributes[idTag,Protected]
SetAttributes[idSetter,HoldAll]
idSetter[var_]:=Function[{content,id},EventHandler[content,{"MouseMoved":>(var=id)}]]

 SetAttributes[dragNdrop,HoldFirst]
 dragNdrop[content_,action_]:=
 DynamicModule[{currentId,from},
 EventHandler[

 Dynamic[Block[{idTag=idSetter[currentId]},content]]

 ,{
  "MouseDown":>(from=currentId),
  "MouseUp":> action[from,currentId]}]
]

So then a call to add a dragNdrop fuctionality on some code is simply:

mygrid = {{1, 2, 5, 7, 9}, {3, 4, 8, 4, 2}, {5, 12, 7, 3, 8}};
dragNdrop[
    Grid[MapIndexed[idTag, mygrid, {2}]]
,action]

Added Variable descriptions

currentId stores the id of the element the mouse last moved over, this is used to determine both the element you drag from and the element you drag to. from is used to store the id you dragged from, since it needs to be saved for when actionis called. in idSetter, content is simply the content of the individual items that can be dragged, so in the Grid example, content would be the individual number in the grid.

share|improve this answer
1  
Cool. Is there a way to indicate that there is an element being dragged? –  Yves Klett Aug 22 '12 at 12:29
1  
@YvesKlett The skeleton of the code is something I worked out previusly, where I also used MouseAppearance to change the cursor to the item being dragged, however that code is quite wrangled up in a lot of other stuff, and not generally applicable. If I recall correctly it's quite bothersome trying to get the positions to match exactly when you begin the dragging. –  jVincent Aug 22 '12 at 12:44
    
@jVincent: Can you please tell what is currentId,content and id –  Jennifer Aug 22 '12 at 13:31
    
@Jennifer I added a short description of these variables. –  jVincent Aug 22 '12 at 13:42

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.