3
$\begingroup$

I have solved the following Eq to get hz:

sol = Solve[(-(-1 + b) (hz^3 + hz^3 Log[hz^4/lamda^4]) + 
     2/3 b hz^3 Log[((Fπ)^4 alpha[3]^2)/(16 lamda^6)]) == 0, hz]

I wanted to check if one the solutions like sol[[4, 1, 2]] satisfies the Eq:

FullSimplify[(-(-1 + b) (hz^3 + hz^3 Log[hz^4/lamda^4]) + 
    2/3 b hz^3 Log[((Fπ)^4 alpha[3]^2)/(16 lamda^6)]) /. 
  hz -> sol[[4, 1, 2]], 
 lamda > 0 && alpha[3] > 0 && Fπ > 0 && b ∈ Reals]

I got the following answer:

1/3 (E^(-1 + (2 b Log[(Fπ^4 alpha[3]^2)/(16 lamda^6)])/(
   3 (-1 + b))))^(3/4) lamda^3 (-3 (-1 + b) (1 + 
      Log[E^(-1 + (2 b Log[(Fπ^4 alpha[3]^2)/(16 lamda^6)])/(
        3 (-1 + b)))]) + 2 b Log[(Fπ^4 alpha[3]^2)/(16 lamda^6)])

It should be zero but Mathematica can not simplify it further. Thanks for your help.

Improve this question
$\endgroup$
4
  • $\begingroup$ Is F[Pi] a variable in itself or F * Pi? $\endgroup$
    – LLlAMnYP
    Oct 8, 2015 at 6:56
  • $\begingroup$ @JasonB, it appears Fπ is indeed the name of a variable and not the product of F and π. Your first edit was correct. At least that's how it looks from the code and the expected result. $\endgroup$
    – LLlAMnYP
    Oct 8, 2015 at 7:06
  • $\begingroup$ okay - I was afraid I messed it up, you never really see Pi as part of a name $\endgroup$
    – Jason B.
    Oct 8, 2015 at 7:07
  • 1
    $\begingroup$ I still have something wrong, when I enter OP's first two commands, it tells me that sol[[4,2,1]] doesn't exist, it finds a single solution $\endgroup$
    – Jason B.
    Oct 8, 2015 at 7:10

2 Answers 2

Reset to default
3
$\begingroup$

I see, you have stated, that all variables are real (some are also positive, but still real). Therefore, ComplexExpand[expr] is equivalent to your expression.

1/3 (E^(-1 + (2 b Log[(Fπ^4 alpha[3]^2)/(16 lamda^6)])/(
   3 (-1 + b))))^(
 3/4) lamda^3 (-3 (-1 + b) (1 + 
      Log[E^(-1 + (2 b Log[(Fπ^4 alpha[3]^2)/(16 lamda^6)])/(
        3 (-1 + b)))]) + 2 b Log[(Fπ^4 alpha[3]^2)/(16 lamda^6)]);

ComplexExpand[%]

(* 0 *)
Improve this answer
$\endgroup$
1
  • $\begingroup$ ComplexExpand[expr] works and results in 0 in version 9.0.0.0, but in version 10.0.1.0, it doesn't yield zero. $\endgroup$
    – Kheeyal
    Oct 9, 2015 at 12:54
1
$\begingroup$

Like Jason B in a Comment, I noticed that 

eq1 = (-(-1 + b) (hz^3 + hz^3 Log[hz^4/lamda^4]) + 
        2/3 b hz^3 Log[((Fπ)^4 alpha[3]^2)/(16 lamda^6)])
sol = Solve[eq1 == 0, hz]

yields only one solution,

(* {{hz -> E^((3 - 3 b - 8 b Log[2] + 8 b Log[Fπ] - 12 Log[lamda] + 
            4 b Log[alpha[3]])/(12 (-1 + b)))}} *)

Hence, sol[[4, 1, 2]] does not exist. (Perhaps, the OP used an older version of Mathematica. I have "10.2.0 for Microsoft Windows (64-bit) (July 7, 2015)".) With the result above,

eq2 = eq1 /. sol[[1, 1]];
FullSimplify[eq2, lamda > 0 && alpha[3] > 0 && Fπ > 0 && b ∈ Reals]

runs at least 30 minutes without returning an answer. Further, 

ComplexExpand[eq2]

provides no simplification. Instead, I used

cf[e_] := 100 Count[e, _Log, {0, Infinity}] + LeafCount[e];
FullSimplify[eq2, lamda > 0 && alpha[3] > 0 && Fπ > 0 && b ∈ Reals, 
    ComplexityFunction -> cf];
FullSimplify[% /. z1_ Log[z2_] :> Log[PowerExpand[z2^z1]], 
    lamda > 0 && alpha[3] > 0 && Fπ > 0 && b ∈ Reals]
(* 0 *)

Evidently, FullSimplify has difficulty simplifying sums of Log with complicated arguments.

Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.